File Coverage

blib/lib/Range/ArrayIter.pm

Criterion	Covered	Total	%
statement	44	45	97.7
branch	18	20	90.0
condition	4	5	80.0
subroutine	8	8	100.0
pod	1	1	100.0
total	75	79	94.9

package Range::ArrayIter;

our $DATE = '2019-04-17'; # DATE
our $VERSION = '0.001'; # VERSION

use strict;
use warnings;

use Exporter qw(import);
our @EXPORT_OK = qw(range_arrayiter);

my $re_num = qr/\A[+-]?[0-9]+(\.[0-9]+)?\z/;

sub range_arrayiter($$;$) {
    my ($start, $end, $step) = @_;

    tie my @ary, 'Range::ArrayIter::Tie', $start, $end, $step;
    \@ary;
}

package # hide from PAUSE
    Range::ArrayIter::Tie;

sub TIEARRAY {
    my $class = shift;
    my ($start, $end, $step) = @_;
    $step //= 1;

    my $self = {
        start => $start,
        end   => $end,
        step  => $step,

        _ended => 0,
        _len   => 0,
        _cur   => $start,
        _buf   => [],
    };

    if ($start =~ $re_num && $end =~ $re_num) {
        $self->{_num}   = 1;
        $self->{_ended}++ if $start > $end;
    } else {
        die "Cannot specify step != 1 for non-numeric range" if $step != 1;
        $self->{_ended}++ if $start gt $end;
    }
    bless $self, $class;
}

sub _next {
    my $self = shift;

    if ($self->{_num}) {
        $self->{_ended}++ if $self->{_cur} > $self->{end};
        return if $self->{_ended};
        push @{ $self->{_buf} }, $self->{_cur};
        $self->{_cur} += $self->{step};
    } else {
        return if $self->{_ended};
        $self->{_ended}++ if $self->{_cur} ge $self->{end};
        push @{ $self->{_buf} }, $self->{_cur}++;
    }
}

sub FETCHSIZE {
    my $self = shift;
    $self->_next;
    $self->{_len} + @{ $self->{_buf} };
}

sub FETCH {
    my $self = shift;
    $self->_next;
    if (@{ $self->{_buf} }) {
        $self->{_len}++;
        shift @{ $self->{_buf} };
    } else {
        undef;
    }
}

1;
# ABSTRACT: Generate a tied-array iterator for range

__END__