File Coverage

blib/lib/RPi/GPIOExpander/MCP23017.pm

Criterion	Covered	Total	%
statement	15	103	14.5
branch	0	44	0.0
condition	0	14	0.0
subroutine	5	24	20.8
pod	14	14	100.0
total	34	199	17.0

package RPi::GPIOExpander::MCP23017;

use strict;
use warnings;

use Carp qw(croak);
use RPi::Const qw(:all);

our $VERSION = '0.01';

require XSLoader;
XSLoader::load('RPi::GPIOExpander::MCP23017', $VERSION);

use constant {
    BANK_A          => 0,
    BANK_B          => 1,
    REG_BITS_ON     => 0xFF,
    REG_BITS_OFF    => 0x00,
};

# operational methods

sub new {
    my ($class, $addr) = @_;
    my $self = bless {}, $class;
    $self->_fd(getFd($addr // 0x20));
    return $self;
}
sub cleanup {
    clean($_[0]->_fd);
}

# pin methods

sub mode {
    my ($self, $pin, $mode) = @_;

    if (! defined $mode){
        my $reg = $pin > 7 ? MCP23017_IODIRB : MCP23017_IODIRA;
        my $bit = _pinBit($pin);
        return getRegisterBit($self->_fd, $reg, $bit);
    }

    _check_mode($mode);

    pinMode($self->_fd, $pin, $mode);
}
sub pullup {
    my ($self, $pin, $state) = @_;

    if (! defined $state){
        my $reg = $pin > 7 ? MCP23017_GPPUB : MCP23017_GPPUA;
        my $bit = _pinBit($pin);
        return getRegisterBit($self->_fd, $reg, $bit);
    }

    _check_pullup($state);

    pullUp($self->_fd, $pin, $state);
}
sub read {
    my ($self, $pin) = @_;
    return readPin($self->_fd, $pin);
}
sub write {
    my ($self, $pin, $state) = @_;

    _check_write($state);

    return writePin($self->_fd, $pin, $state);
}

# bank methods

sub mode_bank {
    my ($self, $bank, $mode) = @_;

    _check_bank($bank);
    my $reg = $bank == BANK_A ? MCP23017_IODIRA : MCP23017_IODIRB;

    if (! defined $mode){
        return getRegister($self->_fd, $reg);
    }

    _check_mode($mode);
    $mode = REG_BITS_ON if $mode == MCP23017_INPUT;

    setRegister($self->_fd, $reg, $mode, "mode_bank()");

    return getRegister($self->_fd, $reg);
}
sub write_bank {
    my ($self, $bank, $state) = @_;

    _check_bank($bank);
    _check_write($state);

    my $reg = $bank == BANK_A ? MCP23017_GPIOA : MCP23017_GPIOB;
    $state = REG_BITS_ON if $state == HIGH;

    setRegister($self->_fd, $reg, $state, "write_bank()");

    return getRegister($self->_fd, $reg);
}
sub pullup_bank {
    my ($self, $bank, $state) = @_;

    _check_bank($bank);

    my $reg = $bank == BANK_A ? MCP23017_GPPUA : MCP23017_GPPUB;

    if (! defined $state){
        return getRegister($self->_fd, $reg);
    }

    _check_pullup($state);

    $state = REG_BITS_ON if $state == HIGH;

    setRegister($self->_fd, $reg, $state, "write_pullup()");

    return getRegister($self->_fd, $reg);
}

# both bank (all) methods

sub mode_all {
    my ($self, $mode) = @_;

    _check_mode($mode);
    $mode = REG_BITS_ON if $mode == MCP23017_INPUT;

    for my $reg (MCP23017_IODIRA .. MCP23017_IODIRB) {
        setRegister($self->_fd, $reg, $mode, "mode_all()");
    }
}
sub write_all {
    my ($self, $state) = @_;

    _check_write($state);
    $state = REG_BITS_ON if $state == HIGH;

    for my $reg (MCP23017_GPIOA .. MCP23017_GPIOB) {
        setRegister($self->_fd, $reg, $state, "write_all()");
    }
}
sub pullup_all {
    my ($self, $state) = @_;

    _check_pullup($state);
    $state = REG_BITS_ON if $state == MCP23017_INPUT;

    for my $reg (MCP23017_GPPUA .. MCP23017_GPPUB) {
        setRegister($self->_fd, $reg, $state, "mode_all()");
    }
}

# register methods

sub register {
    my ($self, $reg, $data) = @_;

    if (defined $data){
        setRegister($self->_fd, $reg, $data, 'register()');
    }
    return getRegister($self->_fd, $reg);
}
sub register_bit {
    my ($self, $reg, $bit) = @_;

    my $regval = getRegisterBit($self->_fd, $reg, $bit);
    return $regval;
}

# internal/helper methods

sub _check_bank {
    my ($bank) = @_;
    if ($bank != BANK_A && $bank != BANK_B){
        croak "bank param must be either 0 or 1, not '$bank'\n";
    }
}
sub _check_mode {
    my ($mode) = @_;
    if ($mode != MCP23017_INPUT && $mode != MCP23017_OUTPUT){
        croak "mode param must be either 0 or 1, not '$mode'\n";
    }
}
sub _check_pullup {
    my ($state) = @_;

    if ($state != HIGH && $state != LOW){
        croak "state param must be either 0 or 1, not '$state'\n";
    }
}
sub _check_write {
    my ($state) = @_;

    if (! defined $state){
        croak "write() requires the state to be sent in\n";
    }

    if ($state != HIGH && $state != LOW){
        croak "state param must be either 0 or 1, not '$state'\n";
    }
}
sub _fd {
    my ($self, $fd) = @_;
    $self->{fd} = $fd if defined $fd;
    return $self->{fd};
}

1;
__END__