File Coverage

blib/lib/RPi/DigiPot/MCP4XXXX.pm

Criterion	Covered	Total	%
statement	10	12	83.3
branch			n/a
condition			n/a
subroutine	4	4	100.0
pod			n/a
total	14	16	87.5

package RPi::DigiPot::MCP4XXXX;

use warnings;
use strict;

our $VERSION = '2.36.2';

use RPi::WiringPi::Constant qw(:all);
use WiringPi::API qw(:all);

sub new {
    if (@_ !=3 && @_ != 4){
        die "new() requires \$cs and \$channel at minimum\n";
    }

    my ($class, $cs, $channel, $speed) = @_;

    my $self = bless {}, $class;
    $self->_cs($cs);
    $self->{len} = 2;

    wiringPiSetupGpio();

    wiringPiSPISetup(
        $self->_channel($channel),
        $self->_speed($speed)
    );

    pinMode($self->_cs, OUTPUT);
    digitalWrite($self->_cs, HIGH);

    return $self;
}
sub set {
    my ($self, $data, $pot) = @_;

    if ($data < 0 || $data > 255){
        die "set() requires 0-255 as the data param\n";
    }

    if (defined $pot){
        if ($pot !=1 && $pot != 2 && $pot != 3){
            die "set() \$pot param must be 1-3\n";
        }
    }

    my $cmd = 0x01;
    $pot = 1 if ! defined $pot;

    my $bytes = $self->_bytes($cmd, $pot, $data);

    digitalWrite($self->_cs, LOW);
    spiDataRW($self->_channel, $bytes, $self->_len);
    digitalWrite($self->_cs, HIGH);
}
sub shutdown {
    my ($self, $pot) = @_;

    if (defined $pot){
        if ($pot !=1 && $pot != 2 && $pot != 3){
            die "set() \$pot param must be 1-3\n";
        }
    }

    my $data = 0;
    my $cmd = 0x02; # shutdown bit
    $pot = 1 if ! defined $pot;

    my $bytes = $self->_bytes($cmd, $pot, $data);

    spiDataRW($self->_channel, $bytes, $self->_len);
}
sub _bytes {

    # calculates and returns an aref of control/data bytes

    my ($self, $cmd, $chan, $data) = @_;

    if (! defined $cmd || ! defined $chan || ! defined $data){
        die "_bytes() requires \$cmd, \$chan (pot) and \$data params\n";
    }

    # shift the command byte left to get a nibble,
    # then OR the channel nibble to it

    my $cntl = ($cmd << 4) | $chan;

    return [$cntl, $data];
}
sub _channel {

    # sets/gets the SPI channel

    my ($self, $chan) = @_;
    $self->{channel} = $chan if defined $chan;

    if ($self->{channel} != 0 && $self->{channel} != 1){
        die "\$channel param must be 0 or 1\n";
    }

    return $self->{channel};
}
sub _cs {

    # sets/gets the chip select (CS) pin

    my ($self, $pin) = @_;

    if (defined $pin && ($pin < 0 || $pin > 63)){
        die "cs() param must be a valid GPIO pin number\n";
    }

    $self->{cs} = $pin if defined $pin;

    if (! defined $self->{cs}){
        die "cs() can't continue, we're not configured with a pin\n";
    }

    return $self->{cs};
}
sub _len {

    # returns the number of bytes to send to SPI
    # this number is hardcoded in new()

    my $self = shift;
    return $self->{len};
}
sub _speed {

    # sets/gets the SPI bus speed

    my ($self, $speed) = @_;
    $self->{speed} = $speed if defined $speed;
    $self->{speed} = 1000000 if ! defined $self->{speed}; # 1 MHz
    return $self->{speed};
}
sub _vim{};

1;
__END__