File Coverage

blib/lib/Pod/Readme/Brief.pm

Criterion	Covered	Total	%
statement	39	39	100.0
branch	9	18	50.0
condition	1	3	33.3
subroutine	7	7	100.0
pod	2	3	66.6
total	58	70	82.8

use strict; use warnings;

package Pod::Readme::Brief;

our $VERSION = '1.001';

use Pod::Text;

sub new { my $class = shift; bless [ split /(?<=\n)/, ( join '', @_ ), -1 ], $class }

sub find_pod_section {
	my ( $self, $section, $do_loose ) = ( shift, @_ );
	my $rx = $do_loose ? ".*?(?i:$section)" : "+(?i:$section)\$";
	my @match = grep /^=head1\s$rx/ ... /^=head1\s/, @$self, "=head1 BUFFER STOP\n";
	pop @match;
	die "$section heading not found in POD\n" unless @match;
	@match;
}

sub render {
	my ( $self, %arg ) = ( shift, @_ );

	my ( $name, @ambiguous ) = grep s/ - .*//s, $self->find_pod_section( NAME => 0 );
	die "Could not parse NAME from the POD\n" unless defined $name and not @ambiguous;

	s/\A\s+//, s/\s+\z// for $name;
	die "Bad module name $name\n" unless $name =~ /\A\w+(?:::\w+)*\z/;

	my @pod = $self->find_pod_section( DESCRIPTION => 0 );
	$pod[0] =~ s/\s.*/ $name/;

	( push @pod, $_ ), $pod[-1] =~ s!^\t!!mg for <<'__HERE__';
	=head1 INSTALLATION

	This is a Perl module distribution. It should be installed with whichever
	tool you use to manage your installation of Perl, e.g. any of

	  cpanm .
	  cpan  .
	  cpanp -i .

	Consult http://www.cpan.org/modules/INSTALL.html for further instruction.
__HERE__

	my $installer = $arg{'installer'};
	( push @pod, $_ ), $pod[-1] =~ s!^\t!!mg for $installer ? <<"__HERE__" : "\n";
	Should you wish to install this module manually, the procedure is
	${ $installer eq 'eumm' ? \'
	  perl Makefile.PL
	  make
	  make test
	  make install
	' : $installer eq 'mb' ? \'
	  perl Build.PL
	  ./Build
	  ./Build test
	  ./Build install
	' : die "Unknown installer $installer\n" }
__HERE__

	push @pod, $self->find_pod_section( LICENSE => 1 );

	my ( $pod, $text ) = join '', "=pod\n\n", @pod;

	open my $in,  '<', \$pod  or die $!;
	open my $out, '>', \$text or die $!;
	my $parser = Pod::Text->new( loose => 1, width => 73, indent => 0 );
	$parser->parse_from_filehandle( $in, $out );
	$text =~ s{\n+\z}{\n};

	$text;
}

1;

__END__