File Coverage

lib/Pod/Headings.pm

Criterion	Covered	Total	%
statement	59	59	100.0
branch	11	12	91.6
condition	2	3	66.6
subroutine	10	10	100.0
pod	1	1	100.0
total	83	85	97.6

package Pod::Headings;

use strict;
use warnings;

use v5.20;

use Pod::Simple;
our @ISA = qw(Pod::Simple);
our $VERSION = '0.02';

use feature 'signatures';
no warnings 'experimental::signatures';

#
# Can pass a list of handlers to new()
#
sub new ($class, @args) {
    my $self = $class->SUPER::new();
    $self->{handlers} = {@args}; # if scalar @args;
    $self->{_elements} = [];
    return $self;
}

sub _handle_element_start ($parser, $element_name, $attr_hash_r) {

    return unless defined $parser->{handlers}{$element_name};
    push @{$parser->{_elements}}, { heading => $element_name, text => '', attrs=> $attr_hash_r };
}

sub _handle_element_end ($parser, $element_name, $attr_hash_r = undef) {

    return unless scalar @{$parser->{_elements}} && ($element_name eq ${$parser->{_elements}}[-1]->{heading});

    my $propagate_text = 0;
    my $this_element = pop @{$parser->{_elements}};
    if (ref $parser->{handlers}{$element_name} eq 'CODE') {
        $propagate_text = $parser->{handlers}{$element_name}->($parser, $element_name, $this_element->{attrs}, $this_element->{text});
    } else {
        $propagate_text = $parser->{handlers}{$element_name};
    }

    if ($propagate_text) {
        if (scalar @{$parser->{_elements}}) {
            ${$parser->{_elements}}[-1]->{text} .= $this_element->{text};
        }
    }

}

sub _handle_text ($parser, $text) {

    ${$parser->{_elements}}[-1]->{text} .= $text if scalar @{$parser->{_elements}};

}

1;

__END__