File Coverage

blib/lib/PlugAuth/Plugin/LDAP.pm

Criterion	Covered	Total	%
statement	32	35	91.4
branch	7	14	50.0
condition	1	3	33.3
subroutine	7	7	100.0
pod	1	1	100.0
total	48	60	80.0

package PlugAuth::Plugin::LDAP;

# ABSTRACT: LDAP back end for PlugAuth
our $VERSION = '0.08'; # VERSION


use strict;
use warnings;
use v5.10;
use Net::LDAP;
use Log::Log4perl qw/:easy/;
use Role::Tiny::With;

with 'PlugAuth::Role::Plugin';
with 'PlugAuth::Role::Auth';


sub check_credentials {
    my ($class, $user,$pw) = @_;
    $user = lc $user;

    my $ldap_config = $class->global_config->ldap(default => '');

    if (!$ldap_config or !$ldap_config->{authoritative}) {
        # Check files first.
        return 1 if $class->deligate_check_credentials($user, $pw);
    }
    return 0 unless $ldap_config;
    my $server = $ldap_config->{server} or LOGDIE "Missing ldap server";
    my $ldap = Net::LDAP->new($server, timeout => 5) or do {
        ERROR "Could not connect to ldap server $server: $@";
        return 0;
    };
    my $orig = $user;
    my $extra = $user =~ tr/a-zA-Z0-9@._-//dc;
    WARN "Invalid username '$orig', turned into $user" if $extra;
    my $dn = sprintf($ldap_config->{dn},$user);
    my $mesg = $ldap->bind($dn, password => $pw);
    $mesg->code or return 1;
    INFO "Ldap returned ".$mesg->code." : ".$mesg->error;
    return 0;
}

1;

__END__