File Coverage

blib/lib/PlugAuth/Plugin/Audit.pm

Criterion	Covered	Total	%
statement	85	89	95.5
branch	6	12	50.0
condition	3	8	37.5
subroutine	16	17	94.1
pod	0	2	0.0
total	110	128	85.9

package PlugAuth::Plugin::Audit;

use strict;
use warnings;
use v5.10;
use Role::Tiny::With;
use Path::Class::Dir;
use Path::Class::File;
use File::HomeDir;
use YAML::XS qw( Dump LoadFile );
use DateTime;

with 'PlugAuth::Role::Plugin';

# ABSTRACT: Audit log for authentication/authorization
our $VERSION = '0.05'; # VERSION


with 'PlugAuth::Role::Plugin';

sub init
{
  my($self) = @_;

  $self->app->routes->route('/audit')->name('audit_check')->get(sub {
    my($c) = @_;
    my ($day,$month,$year) = (localtime(time))[3,4,5];
    $year+=1900;
    $month++;
    $c->stash->{autodata} = {
      today   => join('-', $year, sprintf("%02d", $month), sprintf("%02d", $day)),
      version => $PlugAuth::Plugin::Audit::VERSION // 'dev',
    };
  });

  $self->app->routes->route('/audit/today')->name('audit_today')->get(sub {
    my($c) = @_;
    my ($day,$month,$year) = (localtime(time))[3,4,5];
    $year+=1900;
    $month++;
    $c->redirect_to($c->url_for('audit', year => $year, month => sprintf("%02d", $month), day => sprintf("%02d", $day)));
  });

  # FIXME: provide an interface for this
  # in Clustericious
  my $auth = sub {
    my $c = shift;
    my $plugin = $self->_self_auth_plugin;
    return 1 unless defined $plugin;
    return 0 unless $plugin->authenticate($c, 'ACPS');
    return 0 unless $plugin->authorize($c, 'accounts', $c->req->url->path);
    return 1;
  };

  my $authz = sub {
  };

  $self->app->routes->bridge->to({ cb => $auth })->route('/audit/:year/:month/:day')->name('audit')->get(sub {
    my($c) = @_;
    my $year  = $c->stash('year');
    my $month = $c->stash('month');
    my $day   = $c->stash('day');
    return $c->render_message('not ok', 404)
      unless $year  =~ /^\d\d\d\d$/
      &&     $month =~ /^\d\d?$/
      &&     $day   =~ /^\d\d?$/;
    my $filename = $self->log_filename({ year => $year, month => $month, day => $day });
    return $c->render_message('not ok', 404)
      unless -r $filename;
    my(@events) = map {
      my $event = $_;
      my $dt = DateTime->from_epoch( epoch => $event->{time} );
      $dt->set_time_zone('local');
      $event->{time_epoch}    = delete $event->{time};
      $event->{time_human}    = $dt->strftime("%a, %d %b %Y %H:%M:%S %z");
      $event->{time_computer} = $dt->strftime("%Y-%m-%dT%H:%M:%S%z");
      $event;
    } LoadFile($filename->stringify);
    $c->stash->{autodata} = \@events;
  });

  my @event_names = qw(
    create_user
    delete_user
    create_group
    delete_group
    update_group
    grant
    revoke
    change_password
  );

  foreach my $event_name (@event_names)
  {
    $self->app->on($event_name => sub {
      my($app, $args) = @_;

      my %info = %$args;
      $info{time} = time;
      $info{event} = $event_name;
      my $filename = $self->log_filename($info{time});
      open(my $fh, '>>', $filename->stringify);
      print $fh Dump(\%info);
      close $fh;
    });
  }
}

sub log_filename
{
  my($self, $time) = @_;

  my($day, $month, $year);

  if(ref $time)
  {
    $day   = $time->{day};
    $month = $time->{month};
    $year  = $time->{year};
  }
  else
  {
    ($day,$month,$year) = (localtime($time))[3,4,5];
    $year += 1900;
    $month++;
  }

  my $filename = Path::Class::File->new(
    File::HomeDir->my_home,
    '.plugauth_plugin_audit',
    sprintf("%04d", $year),
    sprintf("%02d", $month),
    sprintf("%02d", $day),
    'audit.log',
  );
  $filename->dir->mkpath(0,0700);
  $filename;
}

1;

__END__