File Coverage

blib/lib/PlugAuth/Client/Tiny.pm

Criterion	Covered	Total	%
statement	42	48	87.5
branch	12	14	85.7
condition	4	5	80.0
subroutine	9	10	90.0
pod	5	5	100.0
total	72	82	87.8

package PlugAuth::Client::Tiny;

use strict;
use warnings;
use 5.006;
use HTTP::Tiny;

# ABSTRACT: (Deprecated) Minimal PlugAuth client
our $VERSION = '0.03'; # VERSION


sub new
{
  my $class = shift;
  my %args = ref $_[0] ? %{$_[0]} : @_;
  my $url = (delete $args{url}) || 'http://localhost:3000/';
  $url =~ s{/?$}{/};
  return bless {
    url    => $url,
    http   => HTTP::Tiny->new(%args),
  }, $class;
}


sub url { shift->{url} }


sub auth
{
  my($self, $user, $password) = @_;

  my $response = $self->{http}->get($self->{url} . 'auth', {
    headers => {
      ## TODO option for setting the realm
      # WWW-Authenticate: Basic realm="..."
      Authorization => 'Basic ' . do {
        ## TODO maybe use MIME::Base64 if available?
        ## it is XS, but may be faster.
        use integer;
        my $a = join(':', $user,$password);
        my $r = pack('u', $a);
        $r =~ s/^.//mg;
        $r =~ s/\n//g;
        $r =~ tr|` -_|AA-Za-z0-9+/|;
        my $p = (3-length($a)%3)%3;
        $r =~ s/.{$p}$/'=' x $p/e if $p;
        $r;
      },
    }
  });

  return 1 if $response->{status} == 200;
  return 0 if $response->{status} == 403
  ||          $response->{status} == 401;

  die $response->{content};
}


sub authz
{
  my($self, $user, $action, $resource) = @_;

  $resource =~ s{^/?}{};
  my $url = $self->{url} . join('/', 'authz', 'user', $user, $action, $resource);
  my $response = $self->{http}->get($url);

  return 1 if $response->{status} == 200;
  return 0 if $response->{status} == 403;
  die $response->{content};
}


sub version
{
  my($self) = @_;

  my $url = $self->{url} . 'version';
  my $response = $self->{http}->get($url);

  return unless $response->{status} == 200;

  # JSON::PP is in core as of 5.14
  require JSON::PP;
  JSON::PP::decode_json($response->{content})->[0];
}

1;

__END__