File Coverage

blib/lib/PlugAuth/Client/Tiny.pm

Criterion	Covered	Total	%
statement	43	43	100.0
branch	12	12	100.0
condition	4	5	80.0
subroutine	9	9	100.0
pod	3	4	75.0
total	71	73	97.2

package PlugAuth::Client::Tiny;

use strict;
use warnings;
use 5.006;
use HTTP::Tiny;

# ABSTRACT: Minimal PlugAuth client
our $VERSION = '0.01'; # VERSION


sub new
{
  my $class = shift;
  my %args = ref $_[0] ? %{$_[0]} : @_;
  my $url = (delete $args{url}) || 'http://localhost:3000/';
  $url =~ s{/?$}{/};
  return bless {
    url    => $url,
    http   => HTTP::Tiny->new(%args),
  }, $class;
}


sub url { shift->{url} }


sub auth
{
  my($self, $user, $password) = @_;

  my $response = $self->{http}->get($self->{url} . 'auth', {
    headers => {
      ## TODO option for setting the realm
      # WWW-Authenticate: Basic realm="..."
      Authorization => 'Basic ' . do {
        ## TODO maybe use MIME::Base64 if available?
        ## it is XS, but may be faster.
        use integer;
        my $a = join(':', $user,$password);
        my $r = pack('u', $a);
        $r =~ s/^.//mg;
        $r =~ s/\n//g;
        $r =~ tr|` -_|AA-Za-z0-9+/|;
        my $p = (3-length($a)%3)%3;
        $r =~ s/.{$p}$/'=' x $p/e if $p;
        $r;
      },
    }
  });

  return 1 if $response->{status} == 200;
  return 0 if $response->{status} == 403
  ||          $response->{status} == 401;

  die $response->{content};
}


sub authz
{
  my($self, $user, $action, $resource) = @_;

  $resource =~ s{^/?}{};
  my $url = $self->{url} . join('/', 'authz', 'user', $user, $action, $resource);
  my $response = $self->{http}->get($url);

  return 1 if $response->{status} == 200;
  return 0 if $response->{status} == 403;
  die $response->{content};
}

1;

__END__