File Coverage

blib/lib/Plack/Session/Store/Transparent.pm

Criterion	Covered	Total	%
statement	60	61	98.3
branch	11	18	61.1
condition	1	3	33.3
subroutine	14	14	100.0
pod	4	4	100.0
total	90	100	90.0

package Plack::Session::Store::Transparent;
use 5.008005;
use strict;
use warnings;
use Carp;
use Scalar::Util qw(blessed);

our $VERSION = "0.03";

use parent 'Plack::Session::Store';

use Plack::Util::Accessor qw(
	origin
	cache
);

sub _check_interface {
	my ($class, $obj) = @_;
	return blessed $obj
		&& $obj->can('fetch')
		&& $obj->can('store')
		&& $obj->can('remove');
}

sub new {
	my ($class, %args) = @_;

	unless ($args{origin}) {
		croak "missing mandatory parameter 'origin'";
	}


	{
		# check origin
		croak 'origin requires fetch, store and remove method'
			unless $class->_check_interface($args{origin});

		# check cache
		my @caches = ( ref($args{cache}) eq 'ARRAY' ? @{ $args{cache} } : $args{cache} );
		for (@caches) {
			next unless $_;
			croak 'cache requires fetch, store and remove method'
				unless $class->_check_interface($_);
		}
	}

	return bless { %args }, $class;
}

sub fetch {
	my ($self, $session_id) = @_;

	my @uppers;
	for my $layer ($self->_layers) {
		if (my $session = $layer->fetch($session_id)) {
			# ignore exceptions for availability
			eval {
				$_->store($session_id, $session) for @uppers;
			};
			return $session;
		}
		unshift(@uppers, $layer);
	}

	return;
}

sub store {
	my ($self, $session_id, $session) = @_;

	my @uppers;
	for my $layer ($self->_layers) {
		eval {
			$layer->store($session_id, $session);
		};
		if (my $e = $@) {
			$_->remove($session_id) for @uppers;
			croak $e;
		}

		push(@uppers, $layer);
	}
}

sub remove {
	my ($self, $session_id) = @_;

	for my $layer ($self->_layers) {
		$layer->remove($session_id);
	}
}

sub _caches {
	my ($self) = @_;
	return [] unless $self->cache;
	return ref($self->cache) eq 'ARRAY' ? $self->cache : [ $self->cache ];
}

sub _layers {
	my ($self) = @_;
	return (@{ $self->_caches }, $self->origin);
}

1;
__END__