File Coverage

blib/lib/Plack/Middleware/Watermark.pm

Criterion	Covered	Total	%
statement	37	38	97.3
branch	10	12	83.3
condition	5	8	62.5
subroutine	9	9	100.0
pod	2	2	100.0
total	63	69	91.3

package Plack::Middleware::Watermark;

use strict;
use warnings;

our $VERSION = '0.01';

use parent qw( Plack::Middleware );
use Plack::Util::Accessor qw( comment );

use Plack::Util;
use Carp ();

sub prepare_app {
    my $self = shift;

    unless ($self->comment) {
        Carp::croak "'comment' is not defined";
    }
}

my %comment_style = (
    'html' => [ '' ],
    'xml'  => [ '' ],
    'css'  => [ '/*', '*/' ],
    'js'   => [ '//', '' ],
);

my %mime_type = (
    # html
    'text/html'             => 'html',
    'application/xhtml+xml' => 'html',
    # xml
    'text/xml'             => 'xml',
    'application/xml'      => 'xml',
    'application/rss+xml'  => 'xml',
    'application/atom+xml' => 'xml',
    # css
    'text/css' => 'css',
    # js
    'text/javascript'        => 'js',
    'application/javascript' => 'js',
);

sub call {
    my $self  = shift;
    my ($env) = @_;

    my $res = $self->app->($env);
    $self->response_cb($res, sub {
        my $res  = shift;
        my $type = Plack::Util::header_get($res->[1], 'Content-Type');
        if ($type && $res->[0] == 200) {
            ($type) = split /;\s*/, $type;
            my ($start, $stop) = @{ $comment_style{$mime_type{$type}||''} || [] };
            if ($start or $stop) {
                return sub {
                    my $chunk = shift;
                    return unless defined $chunk;
                    my $comment = ref $self->comment eq 'CODE' ? $self->comment->($env) : $self->comment;
                    $chunk .= join ' ', $start, $comment, $stop;
                    return $chunk;
                };
            }
        }
    });
}

1;
__END__