File Coverage

blib/lib/Plack/Middleware/Throttle/Lite/Backend/Abstract.pm

Criterion	Covered	Total	%
statement	50	50	100.0
branch	8	8	100.0
condition	2	3	66.6
subroutine	15	15	100.0
pod	8	9	88.8
total	83	85	97.6

package Plack::Middleware::Throttle::Lite::Backend::Abstract;

# ABSTRACT: Base class for Throttle::Lite backends

use strict;
use warnings;
use Carp ();
use POSIX qw/strftime/;

our $VERSION = '0.05'; # VERSION
our $AUTHORITY = 'cpan:CHIM'; # AUTHORITY

sub new {
    my ($class) = shift;
    my $args = defined $_[0] && UNIVERSAL::isa($_[0], 'HASH') ? shift : { @_ };
    my $self = $args;
    bless $self, $class;
    $self->init($args);
    return $self;
}

sub init { 1 }

sub mk_attrs {
    my ($class, @attributes) = @_;

    foreach my $attr (@attributes) {
        my $code = sub {
             my ($self, $value) = @_;
             if (@_ == 1) {
                 return $self->{$attr};
             }
             else {
                 return $self->{$attr} = $value;
             }
         };

        my $method = "${class}::${attr}";
        { no strict 'refs'; *$method = $code; }
    }
}

sub reqs_done { Carp::confess 'method \'reqs_done\' is not implemented' }
sub increment { Carp::confess 'method \'increment\' is not implemented' }

__PACKAGE__->mk_attrs(qw(reqs_max requester_id units));

sub settings {
    my ($self) = @_;

    my $settings = {
        'req/day'  => {
            'interval' => 86400,
            'format'   => '%Y%j',
        },
        'req/hour' => {
            'interval' => 3600,
            'format'   => '%Y%j%H',
        },
        'req/min'  => {
            'format'   => '%Y%j%H%M',
            'interval' => 60,
        },
    };

    $settings->{$self->units};
}

sub expire_in {
    my ($self) = @_;

    my ($sec, $min, $hour) = localtime(time);
    my $interval = $self->settings->{'interval'};

    my $already_passed;

    if ($interval == 86400) {       # req/day
        $already_passed = 3600 * $hour + 60 * $min + $sec;
    }
    elsif ($interval == 3600) {     # req/hour
        $already_passed = 60 * $min + $sec;
    }
    else {                          # req/min
        $already_passed = $sec;
    }

    $interval - $already_passed;
}

sub ymdh {
    my ($self) = @_;

    strftime($self->settings->{'format'} => localtime(time));
}

sub cache_key {
    my ($self) = @_;

    $self->requester_id . ':' . $self->ymdh
}

1; # End of Plack::Middleware::Throttle::Lite::Backend::Abstract

__END__