File Coverage

blib/lib/Plack/Middleware/StackTrace/LinkedSource.pm

Criterion	Covered	Total	%
statement	53	54	98.1
branch	12	18	66.6
condition	3	6	50.0
subroutine	10	10	100.0
pod	2	2	100.0
total	80	90	88.8

package Plack::Middleware::StackTrace::LinkedSource;
use strict;
use warnings;
use parent 'Plack::Middleware::StackTrace';
use Plack::App::SourceViewer;
use Plack::Util;
use Plack::Util::Accessor qw/
    lib
    viewer
    view_root
    force
/;

our $VERSION = '0.14';

sub prepare_app {
    my ($self) = @_;

    if (!$self->lib) {
        $self->lib([@INC]);
    }
    elsif (ref $self->lib ne 'ARRAY') {
        $self->lib([$self->lib]);
    }

    unless ($self->viewer) {
        my $source_viewer = Plack::App::SourceViewer->new(root => $self->lib);
        $source_viewer->prepare_app;
        $self->viewer($source_viewer);
    }

    $self->view_root
        or $self->view_root('/source');

    $self->{_enabled} = ($self->force || !$ENV{PLACK_ENV} || $ENV{PLACK_ENV} eq 'development');
}

sub call {
    my($self, $env) = @_;

    unless ($self->{_enabled}) {
        return $self->app->($env);
    }

    my $path = $self->view_root;

    if ($env->{PATH_INFO} =~ m!^$path!) {
        my $path_info = $env->{PATH_INFO};
        $path_info =~ s!^$path/!!;
        local $env->{PATH_INFO} = $path_info;
        return $self->viewer->call($env);
    }

    my $res = $self->SUPER::call($env);

    if ($res->[0] == 500 && Plack::Util::header_get($res->[1], 'content-type') =~ m!text/html!) {
        my $body = $res->[2][0];
        $self->_add_link(\$body);
        $res->[2][0] = $body;
    }

    return $res;
}

sub _add_link {
    my ($self, $body_ref) = @_;

    for my $lib_path (@{$self->lib}) {
        next if $lib_path eq '.';
        $lib_path =~ s!/!\\!g if $^O eq 'MSWin32';
        ${$body_ref} =~ s!(\Q$lib_path\E[/\\]+([^\.]+\.[^\s]+)\s+line\s+(\d+))[^<]?!$self->_link_html($1, $2, $3)!eg;
    }
}

sub _link_html {
    my ($self, $matched, $path, $line_count) = @_;

    $path =~ s!\\!/!g; # for win

    return qq|$matched|;
}

1;


__END__