File Coverage

blib/lib/Plack/Session/Store/File.pm

Criterion	Covered	Total	%
statement	34	34	100.0
branch	3	4	75.0
condition	3	9	33.3
subroutine	12	12	100.0
pod	4	4	100.0
total	56	63	88.8

package Plack::Session::Store::File;
use strict;
use warnings;

our $VERSION   = '0.23';
our $AUTHORITY = 'cpan:STEVAN';

use Storable ();

use parent 'Plack::Session::Store';

use Plack::Util::Accessor qw[
    dir
    serializer
    deserializer
];

sub new {
    my ($class, %params) = @_;

    $params{'dir'} ||= $ENV{TMPDIR} || '/tmp';

    die "Storage directory (" . $params{'dir'} . ") is not writeable"
        unless -w $params{'dir'};

    $params{'serializer'}   ||= sub { Storable::lock_nstore( @_ ) };
    $params{'deserializer'} ||= sub { Storable::lock_retrieve( @_ ) };

    bless { %params } => $class;
}

sub fetch {
    my ($self, $session_id) = @_;

    my $file_path = $self->_get_session_file_path( $session_id );
    return unless -f $file_path;

    $self->deserializer->( $file_path );
}

sub store {
    my ($self, $session_id, $session) = @_;
    my $file_path = $self->_get_session_file_path( $session_id );
    $self->serializer->( $session, $file_path );
}

sub remove {
    my ($self, $session_id) = @_;
    unlink $self->_get_session_file_path( $session_id );
}

sub _get_session_file_path {
    my ($self, $session_id) = @_;
    $self->dir . '/' . $session_id;
}

1;

__END__