File Coverage

blib/lib/Plack/Middleware/ProcessTimes.pm

Criterion	Covered	Total	%
statement	37	37	100.0
branch	4	4	100.0
condition			n/a
subroutine	7	7	100.0
pod	1	1	100.0
total	49	49	100.0

package Plack::Middleware::ProcessTimes;
$Plack::Middleware::ProcessTimes::VERSION = '0.001000';
use strict;
use warnings;

# ABSTRACT: Include process times of a request in the Plack env

use Time::HiRes qw(time);
use parent 'Plack::Middleware';
use Plack::Util::Accessor qw( measure_children );

sub call {
  my ($self, $env) = @_;

  my @times = (time, times);

  my $res = $self->app->($env);

  return $self->response_cb($res, sub{
    my $inner = shift;

    if ($self->measure_children) {
       1 while waitpid(-1, 1) > 0;
    }

    @times = map { $_ - shift @times } time, times;

    my $CPU = 0;
    $CPU += $times[$_] for 1..4;
    push @times, $CPU;

    @times = map { sprintf "%.3f", $_ } @times;

    push @{$inner->[1]},
      x_time_real      => $times[0],
      x_time_cpu_user  => $times[1],
      x_time_cpu_sys   => $times[2];

    if ($self->measure_children) {
      push @{$inner->[1]},
        x_time_cpu_cuser => $times[3],
        x_time_cpu_csys  => $times[4];
    } else {
      push @{$inner->[1]},
        x_time_cpu_cuser => '-',
        x_time_cpu_csys  => '-';
    };

    return;
  });
}

1;

__END__