File Coverage

blib/lib/Plack/Middleware/Matomo.pm

Criterion	Covered	Total	%
statement	62	66	93.9
branch	9	12	75.0
condition	5	10	50.0
subroutine	11	12	91.6
pod	1	1	100.0
total	88	101	87.1

package Plack::Middleware::Matomo;

our $VERSION = '0.05';

use strict;
use warnings;
use AnyEvent::HTTP;
use Log::Any '$log';
use Plack::Request;
use Plack::Util::Accessor
    qw(apiv base_url idsite token_auth time_format oai_identifier_format view_paths download_paths);
use URI;

use parent 'Plack::Middleware';

sub call {
    my ($self, $env) = @_;

    my $request = Plack::Request->new($env);
    my $res     = $self->app->($env);

    # only get requests
    return $res unless $request->method =~ m{^get$}i;

    my ($action, $id);
    my $view_paths     = $self->view_paths;
    my $download_paths = $self->download_paths;

    $log->info("Entering Matomo middleware at " . $request->path);

    foreach my $p (@$view_paths) {
        if ($request->path =~ /$p/) {
            $id     = $1;
            $action = "view";
            last;
        }
    }
    foreach my $p (@$download_paths) {
        if ($request->path =~ /$p/) {
            $id     = $1;
            $action = "download";
            last;
        }
    }

    return $res unless $action;
    $log->info("Action: $action");

    my $time_format = $self->time_format // '%Y-%m-%dT%H:%M:%SZ';
    my $ip          = $self->_anonymize_ip($request->address);
    my $oai_id      = sprintf($self->oai_identifier_format, $id);
    my $cvar        = '{"1":["oaipmhID","' . $oai_id . '"]}';

    my $rand = int(rand(10000));

    my $event = {
        _id         => $request->session // '',
        action_name => $action,
        apiv        => $self->apiv // 1,
        cvar        => $cvar,
        idsite      => $self->idsite,
        rand        => $rand,
        rec         => 1,
        token_auth  => $self->token_auth,
        ua          => $request->user_agent // 'Mozilla',
        url         => $request->uri,
        urlref      => $request->referer // '',
        visitIP     => $ip,
    };

    if ($action eq 'download') {
        $event->{download} = $request->uri;
    }

    $self->_push_to_matomo($event);

    return $res;
}

sub _anonymize_ip {
    my ($self, $ip) = @_;

    $ip =~ s/\.\d+?$/\.0/;

    return $ip;
}

sub _push_to_matomo {
    my ($self, $event) = @_;

    my $uri = URI->new($self->base_url);
    $uri->query_form($event);

    $log->debug("URL: " . $uri->as_string);

    http_head $uri->as_string, sub {
        my ($body, $hdr) = @_;

       if ($hdr->{Status} =~ /^2/) {
          $log->debug("Ok matomo endpoint: $hdr->{Status} $hdr->{Reason} for " . $uri->as_string);
       } else {
          $log->error("Could not reach matomo endpoint: $hdr->{Status} $hdr->{Reason} for " . $uri->as_string);
       }
   };
}

1;

__END__