File Coverage

blib/lib/Plack/Middleware/LogErrors.pm

Criterion	Covered	Total	%
statement	27	27	100.0
branch	6	6	100.0
condition	9	11	81.8
subroutine	10	10	100.0
pod	2	2	100.0
total	54	56	96.4

use strict;
use warnings;
package Plack::Middleware::LogErrors;
# git description: v0.001-13-g28c86df
$Plack::Middleware::LogErrors::VERSION = '0.002';
# ABSTRACT: Map psgi.errors to psgix.logger or other logger
# KEYWORDS: plack middleware errors logging environment I/O handle

use parent 'Plack::Middleware';

use Plack::Util::Accessor 'logger';
use Scalar::Util 'reftype';

sub prepare_app
{
    my $self = shift;
    die "'logger' is not a coderef!"
        if $self->logger and not __isa_coderef($self->logger);
}

sub call
{
    my ($self, $env) = @_;

    my $logger = $self->logger || $env->{'psgix.logger'};

    die 'no psgix.logger in $env; cannot map psgi.errors to it!'
        if not $logger;

    # convert to something that matches the psgi.errors specs
    $env->{'psgi.errors'} = Plack::Middleware::LogErrors::LogHandle->new($logger);

    return $self->app->($env);
}

sub __isa_coderef
{
    ref $_[0] eq 'CODE'
        or (reftype($_[0]) || '') eq 'CODE'
        or overload::Method($_[0], '&{}')
}

package Plack::Middleware::LogErrors::LogHandle;
# git description: v0.001-13-g28c86df
$Plack::Middleware::LogErrors::LogHandle::VERSION = '0.002';
# ABSTRACT: convert psgix.logger-like logger into an IO::Handle-like object

sub new
{
    my ($class, $logger) = @_;
    return bless { logger => $logger }, $class;
}

sub print
{
    my ($self, $message) = @_;
    $self->{logger}->({
        level => 'error',
        message => $message,
    });
}

1;

__END__