File Coverage

blib/lib/Plack/Middleware/Log/Minimal.pm

Criterion	Covered	Total	%
statement	40	40	100.0
branch	13	14	92.8
condition	6	8	75.0
subroutine	12	12	100.0
pod	2	3	66.6
total	73	77	94.8

package Plack::Middleware::Log::Minimal;
use strict;
use warnings;
use parent qw(Plack::Middleware);
use Plack::Util::Accessor qw( autodump loglevel formatter encoding);
use Log::Minimal 0.09;
use Carp qw/croak/;
use Encode;

our $VERSION = '0.06';

sub build_logger {
    my ($self, $env) = @_;
    return sub {
        my ( $time, $type, $message, $trace, $raw_message) = @_;
        $message = Encode::encode($self->encoding,$message) if Encode::is_utf8($message);
        $env->{'psgi.errors'}->print($self->formatter->($env, $time, $type, $message, $trace, $raw_message));
    };
}


sub prepare_app {
    my $self = shift;
    $self->formatter(sub{
        my ($env, $time, $type, $message, $trace, $raw_message) = @_;
        sprintf "%s [%s] [%s] %s at %s\n", $time, $type, $env->{REQUEST_URI}, $message, $trace;
    }) unless $self->formatter;

    my $encoding = find_encoding($self->encoding || 'utf8');
    croak(sprintf 'encoding %s no found', $self->encoding) unless ref $encoding;
    $self->encoding($encoding);
}

sub call {
    my ($self, $env) = @_;
    local $Log::Minimal::PRINT = $self->build_logger($env);
    local $ENV{$Log::Minimal::ENV_DEBUG} = ($ENV{PLACK_ENV} && $ENV{PLACK_ENV} eq 'development') ? 1 : 0;
    local $Log::Minimal::AUTODUMP = 1 if $self->autodump;
    local $Log::Minimal::COLOR = 1 if $ENV{PLACK_ENV} && $ENV{PLACK_ENV} eq 'development';
    local $Log::Minimal::LOG_LEVEL = $self->loglevel if $self->loglevel;
    $self->app->($env);
}

1;
__END__