File Coverage

blib/lib/Plack/Middleware/Headers.pm

Criterion	Covered	Total	%
statement	53	53	100.0
branch	24	24	100.0
condition	9	9	100.0
subroutine	10	10	100.0
pod	2	2	100.0
total	98	98	100.0

package Plack::Middleware::Headers;
#ABSTRACT: modify HTTP response headers

use strict;
use 5.008_001;
use parent qw(Plack::Middleware);
use Plack::Util::Accessor qw(set append unset code when);

use Plack::Util;
use Scalar::Util qw(reftype);

our $VERSION = '0.11'; #VERSION

sub prepare_app {
    my $self = shift;

    if (ref $self->when and ref $self->when eq 'ARRAY') {
        my @when  = @{$self->when};
        $self->when( sub {
            my @headers = @_;
            my $match = 0;
            for (my $i = 0; $i < @when; $i += 2) {
                my ($key, $check) = ($when[ $i ], $when[ $i + 1 ]);

                my $value = Plack::Util::header_get(\@headers, $key);

                if (!defined $check) {            # missing header check
                    next if defined $value;
                } elsif( !defined $value ) {      # header missing
                    next;
                } elsif( ref $check ) {           # regex match header
                    next if $value !~ $check;
                } elsif ( $value ne $check ) {    # exact header
                    next;
                }

                return 1;
            }
            return;
        });
    }
}

sub call {
    my $self = shift;
    my $res  = $self->app->(@_);

    $self->response_cb(
        $res,
        sub {
            my $res = shift;

            if ($self->code and $self->code ne $res->[0]) {
                return;
            }

            my $headers = $res->[1];

            if ($self->when and !$self->when->(@$headers)) {
                return;
            }

            if ( $self->set ) {
                Plack::Util::header_iter(
                    $self->set, sub {Plack::Util::header_set($headers, @_)}
                );
            }
            if ( $self->append ) {
                push @$headers, @{$self->append};
            }
            if ( $self->unset ) {
                Plack::Util::header_remove($headers, $_) for @{$self->unset};
            }
        }
    );
}

1;

__END__