File Coverage

blib/lib/Plack/Middleware/FileWrap.pm

Criterion	Covered	Total	%
statement	42	44	95.4
branch	8	14	57.1
condition	1	3	33.3
subroutine	8	8	100.0
pod	1	1	100.0
total	60	70	85.7

package Plack::Middleware::FileWrap;
{
    $Plack::Middleware::FileWrap::VERSION = '0.01';
}

# ABSTRACT: Wrap file with headers/footers in Plack

use strict;
use warnings;
use parent qw( Plack::Middleware );

use Plack::Util;
use Plack::Util::Accessor qw( headers footers );

sub call {
    my ( $self, $env ) = @_;

    my $headers = _wrap_files( $self->headers );
    my $footers = _wrap_files( $self->footers );
    return $self->app->($env) unless defined($headers) or defined($footers);

    $self->response_cb(
        $self->app->($env),
        sub {
            my $res = shift;

            if ( defined $res->[2] ) {    # do we need it?
                my $body;
                Plack::Util::foreach( $res->[2], sub { $body .= $_[0] } );
                my $new_body = $headers . $body . $footers;
                $res->[2] = [$new_body];
                my $h = Plack::Util::headers( $res->[1] );
                $h->set( 'Content-Length', length $new_body );
            }
        }
    );
}

sub _wrap_files {
    my ($files) = @_;

    return unless defined $files;
    return $$files if ref $files eq 'SCALAR';    # \''
    unless ( ref $files ) {                      # '/path/to/file'
        $files = [$files];
    }

    my $body;
    foreach my $file (@$files) {
        if ( ref $file eq 'SCALAR' ) {
            $body .= $$file;
        }
        else {
            if ( open( my $fh, '<', $file ) ) {
                local $/;
                $body .= <$fh>;
                close($fh);
            }
            else {
                warn "[FileWrap] Can't open $file: $!\n";
            }
        }
    }

    return $body;
}

1;

__END__