File Coverage

blib/lib/Plack/Middleware/Antibot.pm

Criterion	Covered	Total	%
statement	57	57	100.0
branch	13	14	92.8
condition	2	5	40.0
subroutine	9	9	100.0
pod	2	2	100.0
total	83	87	95.4

package Plack::Middleware::Antibot;

use strict;
use warnings;

use parent 'Plack::Middleware';

our $VERSION = "0.02";

use List::Util qw(sum reduce);
use Plack::Util ();
use Plack::Util::Accessor qw(filters fall_through max_score);

sub prepare_app {
    my $self = shift;

    $self->{max_score} ||= 0.8;

    my $filters_names = $self->filters;

    my @filters;
    foreach my $filter (@$filters_names) {
        my @args;
        if (ref $filter eq 'ARRAY') {
            my $ref = $filter;
            $filter = shift @$ref;
            @args   = @$ref;
        }

        my $filter_class = __PACKAGE__ . '::' . $filter;

        Plack::Util::load_class($filter_class);

        push @filters, $filter_class->new(@args);
    }

    $self->filters(\@filters);

    return $self;
}

sub call {
    my $self = shift;
    my ($env) = @_;

    my @scores;
    my $current_score = 0;
    foreach my $filter (@{$self->filters}) {
        my $res = $filter->execute($env);
        return $res if $res && ref $res eq 'ARRAY';

        my $name = (split /::/, ref $filter)[-1];
        my $key = 'plack.antibot.' . lc($name) . '.detected';

        if ($env->{$key}) {
            push @scores, $filter->score;

            if (@scores > 1) {
                my $p = sum @scores;
                my $q = reduce { $a * $b } @scores;

                $current_score = $p - $q;
            }
            else {
                $current_score = $filter->score;
            }
        }

        last if $current_score >= $self->max_score;
    }

    $env->{'plack.antibot.score'} = $current_score;

    if ($current_score >= $self->max_score) {
        $env->{'plack.antibot.detected'} = 1;

        return [400, [], ['Bad request']] unless $self->fall_through;
    }

    return $self->app->($env);
}

1;
__END__