File Coverage

blib/lib/Plack/Middleware/I18N.pm

Criterion	Covered	Total	%
statement	76	76	100.0
branch	33	38	86.8
condition	8	9	88.8
subroutine	17	17	100.0
pod	2	2	100.0
total	136	142	95.7

package Plack::Middleware::I18N;

use strict;
use warnings;

use parent 'Plack::Middleware';

use Carp qw(croak);
use List::Util qw(first);
use I18N::AcceptLanguage;

use Plack::Util::Accessor qw(i18n use_path use_session use_header custom_cb);

sub prepare_app {
    my $self = shift;

    croak 'i18n required' unless $self->{i18n};

    $self->{use_path}    = 1 unless defined $self->{use_path};
    $self->{use_session} = 1 unless defined $self->{use_session};
    $self->{use_header}  = 1 unless defined $self->{use_header};

    return $self;
}

sub call {
    my $self = shift;
    my ($env) = @_;

    $self->_detect_language($env);

    return $self->app->($env);
}

sub _detect_language {
    my $self = shift;
    my ($env) = @_;

    my $lang;
    $lang = $self->_detect_from_path($env) if $self->use_path;
    $lang ||= $self->_detect_from_session($env) if $self->use_session;
    $lang ||= $self->_detect_from_header($env)  if $self->use_header;
    $lang = $self->_detect_from_custom_cb($env, $lang) if $self->custom_cb;

    $lang ||= $self->i18n->default_language;

    $env->{'plack.i18n'}          = $self->i18n;
    $env->{'plack.i18n.language'} = $lang;
    $env->{'plack.i18n.handle'}   = $self->i18n->handle($lang);

    if ($self->{use_session}) {
        $env->{'psgix.session'}->{'plack.i18n.language'} = $lang;
    }
}

sub _detect_from_session {
    my $self = shift;
    my ($env) = @_;

    return unless my $session = $env->{'psgix.session'};

    return unless my $lang = $session->{'plack.i18n.language'};

    return unless $self->_is_allowed($lang);

    return $lang;
}

sub _detect_from_path {
    my $self = shift;
    my ($env) = @_;

    my $path = $env->{PATH_INFO};

    my $languages_re = join '|', $self->i18n->languages;
    if ($path =~ s{^/($languages_re)(?=/|$)}{}) {
        $env->{PATH_INFO} = $path;
        return $1 if $self->_is_allowed($1);
    }

    return;
}

sub _detect_from_header {
    my $self = shift;
    my ($env) = @_;

    return unless my $accept_header = $env->{HTTP_ACCEPT_LANGUAGE};

    return
      unless my $lang =
      $self->_build_acceptor->accepts($accept_header, [$self->i18n->languages]);

    return unless $self->_is_allowed($lang);

    return $lang;
}

sub _detect_from_custom_cb {
    my $self = shift;
    my ($env, $detected_lang) = @_;

    my $lang = $self->custom_cb->($env, $detected_lang);

    return unless $lang;

    return unless $self->_is_allowed($lang);

    return $lang;
}

sub _build_acceptor {
    my $self = shift;

    return I18N::AcceptLanguage->new();
}

sub _is_allowed {
    my $self = shift;
    my ($lang) = @_;

    return !!first { $lang eq $_ } $self->i18n->default_language,
      $self->i18n->languages;
}

1;
__END__