File Coverage

blib/lib/Plack/App/Tags/HTML.pm

Criterion	Covered	Total	%
statement	64	69	92.7
branch	17	24	70.8
condition			n/a
subroutine	12	12	100.0
pod			n/a
total	93	105	88.5

package Plack::App::Tags::HTML;

use base qw(Plack::Component::Tags::HTML);
use strict;
use warnings;

use English;
use Error::Pure qw(err);
use Plack::Util::Accessor qw(component constructor_args data data_css data_init data_prepare);
use Symbol::Get;

our $VERSION = 0.14;

sub _css {
	my ($self, $env) = @_;

	if ($self->{'_component'}->can('process_css')) {
		my @data_css;
		if (defined $self->data_css) {
			push @data_css, @{$self->data_css};
		}

		$self->{'_component'}->process_css(@data_css);
	}

	return;
}

sub _loaded_component {
	my ($self, $component) = @_;

	my @names = eval {
		Symbol::Get::get_names($component);
	};
	if ($EVAL_ERROR) {
		return 0;
	}

	return 1;
}

sub _prepare_app {
	my $self = shift;

	$self->SUPER::_prepare_app();

	my %p = (
		'css' => $self->css,
		'tags' => $self->tags,
	);

	my $component = $self->component;
	if (! $self->_loaded_component($component)) {
		eval "require $component;";
		if ($EVAL_ERROR) {
			err "Cannot load component '$component'.",
				'Error', $EVAL_ERROR;
		}
	}
	$self->{'_component'} = $component->new(
		%p,
		defined $self->constructor_args ? (
			%{$self->constructor_args},
		) : (),
	);
	if (! $self->{'_component'}->isa('Tags::HTML')) {
		err "Component must be a instance of 'Tags::HTML' class.";
	}

	# Init prepared data.
	if ($self->{'_component'}->can('prepare')) {
		my @data = ();
		if (defined $self->data_prepare) {
			push @data, @{$self->data_prepare};
		}
		$self->{'_component'}->prepare(@data);
	}

	return;
}

sub _process_actions {
	my ($self, $env) = @_;

	if ($self->{'_component'}->can('init')) {
		my @data = ();
		if (defined $self->data_init) {
			push @data, @{$self->data_init};
		}
		$self->{'_component'}->init(@data);
	}

	return;
}

sub _tags_middle {
	my ($self, $env) = @_;

	my @data;
	if (defined $self->data) {
		push @data, @{$self->data};
	}
	$self->{'_component'}->process(@data);

	return;
}

1;

__END__