File Coverage

blib/lib/Plack/App/ServiceStatus.pm

Criterion	Covered	Total	%
statement	63	78	80.7
branch	10	16	62.5
condition			n/a
subroutine	15	17	88.2
pod	1	2	50.0
total	89	113	78.7

package Plack::App::ServiceStatus;

# ABSTRACT: Check and report status of various services needed by your app

our $VERSION = '0.911'; # VERSION

use 5.024;
use strict;
use warnings;

use base 'Class::Accessor::Fast';
__PACKAGE__->mk_accessors(qw(app version checks show_hostname buildinfo));

use Try::Tiny;
use Plack::Response;
use JSON::MaybeXS;
use Sys::Hostname qw(hostname);
use Module::Runtime qw(use_module);
use Log::Any qw($log);
use Path::Tiny;
use POSIX qw(strftime);

my $startup = time();

sub new {
    my ( $class, %args ) = @_;

    my %attr =
      map { $_ => delete $args{$_} } qw(app version show_hostname buildinfo);
    $attr{checks} = [];

    while ( my ( $key, $value ) = each %args ) {
        my $module;
        if ( $key =~ /^\+/ ) {
            $module = $key;
            $module =~ s/^\+//;
        }
        else {
            $module = 'Plack::App::ServiceStatus::' . $key;
        }
        try {
            use_module($module);
            push(
                $attr{checks}->@*,
                {
                    class => $module,
                    name  => $key,
                    args  => $value
                }
            );
        }
        catch {
            $log->errorf( "%s: cannot init %s: %s", __PACKAGE__, $module, $_ );
        };
    }

    return bless \%attr, $class;
}

sub to_app {
    my $self = shift;

    my $hostname = $self->show_hostname ? hostname() : '';

    my $buildinfo;
    if ( $self->buildinfo ) {
        if ( -f $self->buildinfo ) {
            $buildinfo =
              eval { decode_json( path( $self->buildinfo )->slurp_utf8 ) };
            if ($@) {
                $buildinfo = { status => 'error', message => $@ };
            }
        }
        else {
            $buildinfo = {
                status  => 'error',
                message => 'cannot read buildinfo from ' . $self->buildinfo
            };
        }
    }

    my $app = sub {
        my $env = shift;

        my $json = {
            app                => $self->app,
            started_at_iso8601 => strftime( '%Y-%m-%dT%H:%M:%SZ', gmtime($startup) ),
            started_at         => $startup,
            uptime             => time() - $startup,
        };
        $json->{version}   = $self->version;
        $json->{hostname}  = $hostname  if $hostname;
        $json->{buildinfo} = $buildinfo if $buildinfo;

        my @results = (
            {
                name   => $self->app,
                status => 'ok',
            }
        );

        foreach my $check ( @{ $self->checks } ) {
            my ( $status, $message ) = try {
                return $check->{class}->check( $check->{args} );
            }
            catch {
                return 'nok', "$_";
            };
            my $result = {
                name   => $check->{name},
                status => $status,
            };
            $result->{message} = $message if ($message);

            push( @results, $result );
        }
        $json->{checks} = \@results;

        return Plack::Response->new( 200,
            [ 'Content-Type', 'application/json' ],
            encode_json($json) )->finalize;
    };
    return $app;
}

1;

__END__