File Coverage

blib/lib/Plack/App/Login.pm

Criterion	Covered	Total	%
statement	69	69	100.0
branch	16	16	100.0
condition	4	6	66.6
subroutine	16	16	100.0
pod	2	2	100.0
total	107	109	98.1

package Plack::App::Login;

use base qw(Plack::Component);
use strict;
use warnings;

use CSS::Struct::Output::Raw;
use Error::Pure qw(err);
use Plack::Util::Accessor qw(css generator login_link login_title tags title);
use Scalar::Util qw(blessed);
use Tags::HTML::Login::Button;
use Tags::HTML::Page::Begin;
use Tags::HTML::Page::End;
use Tags::Output::Raw;
use Unicode::UTF8 qw(decode_utf8 encode_utf8);

our $VERSION = 0.06;

sub call {
	my ($self, $env) = @_;

	$self->_tags;
	$self->tags->finalize;
	my $content = encode_utf8($self->tags->flush(1));

	return [
		200,
		[
			'content-type' => 'text/html; charset=utf-8',
		],
		[$content],
	];
}

sub prepare_app {
	my $self = shift;

	if ($self->css) {
		if (! blessed($self->css) || ! $self->css->isa('CSS::Struct::Output')) {
			err "Bad 'CSS::Struct::Output' object.";
		}
	} else {
		$self->css(CSS::Struct::Output::Raw->new);
	}

	if ($self->tags) {
		if (! blessed($self->tags) || ! $self->tags->isa('Tags::Output')) {
			err "Bad 'Tags::Output' object.";
		}
	} else {
		$self->tags(Tags::Output::Raw->new('xml' => 1));
	}

	if (! $self->generator) {
		$self->generator(__PACKAGE__.'; Version: '.$VERSION);
	}

	if (! $self->title) {
		$self->title('Login page');
	}

	if (! $self->login_link) {
		$self->login_link('login');
	}

	if (! $self->login_title) {
		$self->login_title('LOGIN');
	}

	# Tags helper for login button.
	$self->{'_login_button'} = Tags::HTML::Login::Button->new(
		'css' => $self->css,
		'link' => $self->login_link,
		'tags' => $self->tags,
		'title' => $self->login_title,
	);

	return;
}

sub _css {
	my $self = shift;

	$self->{'_login_button'}->process_css;

	return;
}

sub _tags {
	my $self = shift;

	$self->_css;

	Tags::HTML::Page::Begin->new(
		'css' => $self->css,
		'generator' => $self->generator,
		'lang' => {
			'title' => $self->title,
		},
		'tags' => $self->tags,
	)->process;
	$self->{'_login_button'}->process;
	Tags::HTML::Page::End->new(
		'tags' => $self->tags,
	)->process;

	return;
}

1;

__END__