File Coverage

blib/lib/Plack/App/GitHubPages/Faux.pm

Criterion	Covered	Total	%
statement	44	44	100.0
branch	8	8	100.0
condition	3	3	100.0
subroutine	9	9	100.0
pod	0	3	0.0
total	64	67	95.5

package Plack::App::GitHubPages::Faux 0.03 {

  use strict;
  use warnings;
  use 5.020;
  use parent 'Plack::App::File';
  use experimental qw( signatures postderef );
  use Path::Tiny qw( path );

  # ABSTRACT: PSGI app to test your GitHub Pages site


  sub should_handle ($self, $file)
  {
    return -f $file || -d $file;
  }

  sub serve_path ($self, $env, $path, $fullpath=undef)
  {
    if(-d $path)
    {
      my $uri = $env->{PATH_INFO};
      my $index = path($path)->child('index.html')->stringify;
      return $self->return_404 unless -f $index;
      if($uri =~ m{/$})
      {
        $path = $index;
      }
      else
      {
        return
          [ 301,
            [
              'Location'       => "$uri/",
              'Content-Type'   => 'text/plain',
              'Content-Length' => 8,
            ],
            [ 'Redirect' ],
          ];
      }
    }

    return $self->SUPER::serve_path($env, $path, $fullpath);
  }

  sub return_404 ($self)
  {
    my $file = path($self->root)->child('404.html')->stringify;

    -f $file
      ? do {
        my $res = $self->serve_path(undef, $file);
        $res->[0] = '404';
        $res;
      }
      : $self->SUPER::return_404;
  }

}

1;

__END__