File Coverage

blib/lib/Plack/App/EventSource.pm

Criterion	Covered	Total	%
statement	37	37	100.0
branch	5	6	83.3
condition			n/a
subroutine	8	8	100.0
pod	1	1	100.0
total	51	52	98.0

package Plack::App::EventSource;
use 5.008001;
use strict;
use warnings;

use parent 'Plack::Component';

our $VERSION = "0.02";

use Plack::Util::Accessor qw(handler_cb headers);
use Plack::App::EventSource::Connection;

sub call {
    my $self = shift;
    my ($env) = @_;

    return [405, [], ['Method not allowed']]
      unless $env->{REQUEST_METHOD} eq 'GET';

    return sub {
        my $respond = shift;

        my $writer = $respond->(
            [
                200,
                [
                    'Content-Type' => 'text/event-stream; charset=UTF-8',
                    'Cache-Control' =>
                      'no-store, no-cache, must-revalidate, max-age=0',
                    'Access-Control-Allow-Methods' => 'GET',
                    @{$self->headers || []}
                ]
            ]
        );

        my $connection = Plack::App::EventSource::Connection->new(
            push_cb => sub {
                my (@messages) = @_;

                foreach my $msg (@messages) {
                    if (ref $msg eq 'HASH') {
                        my $event = join "\x0d\x0a",
                            map { "$_: ".$msg->{$_} }
                            grep { defined $msg->{$_} }
                            qw(event id data retry);
                         $writer->write("$event\x0d\x0a");
                    }
                    else {
                        $writer->write("data: $msg\x0d\x0a");
                    }
                }

                $writer->write("\x0d\x0a");
            },
            close_cb => sub {
                $writer->close;
            }
        );

        $self->{handler_cb}->($connection, $env);
    };
}

1;
__END__