File Coverage

blib/lib/Plack/Middleware/AccessLog/Timed.pm

Criterion	Covered	Total	%
statement	43	45	95.5
branch	10	12	83.3
condition	1	2	50.0
subroutine	7	8	87.5
pod	1	1	100.0
total	62	68	91.1

package Plack::Middleware::AccessLog::Timed;
use strict;
use warnings;
use parent qw( Plack::Middleware::AccessLog );

use Time::HiRes;
use Plack::Util;

sub call {
    my $self = shift;
    my($env) = @_;

    my $time = [Time::HiRes::gettimeofday];
    my $length = 0;
    my $logger = $self->logger || sub { $env->{'psgi.errors'}->print(@_) };

    my $res = $self->app->($env);

    return $self->response_cb($res, sub {
        my $res = shift;
        my($status, $header, $body) = @$res;

        if (!defined $body) {
            my $length;

            return sub {
                my $line = shift;

                $length += length $line if defined $line;

                unless( defined $line ) {
                    my $now = [Time::HiRes::gettimeofday];
                    $logger->( $self->log_line($status, $header, $env, { time => scalar Time::HiRes::tv_interval($time, $now) * 1_000_000, content_length => $length }) );
                }

                return $line;
            };
        }

        my $getline = ref $body eq 'ARRAY' ? sub { shift @$body } : sub { $body->getline };

        my $timer_body = Plack::Util::inline_object(
            getline => sub {
                my $line = $getline->();
                $length += length $line if defined $line;
                return $line;
            },
            close => sub {
                $body->close if ref $body ne 'ARRAY';

                my $now = [Time::HiRes::gettimeofday];
                $logger->( $self->log_line($status, $header, $env, { time => scalar Time::HiRes::tv_interval($time, $now) * 1_000_000, content_length => $length }) );
            },
        );

        @$res = ($status, $header, $timer_body);
    });
}

1;

__END__