File Coverage

blib/lib/Pinwheel/Model/Time.pm

Criterion	Covered	Total	%
statement	67	67	100.0
branch	18	20	90.0
condition	10	10	100.0
subroutine	30	30	100.0
pod	0	21	0.0
total	125	148	84.4

package Pinwheel::Model::Time;

use strict;
use warnings;

use POSIX qw();
use Time::Local qw(timegm_nocheck timelocal_nocheck);

use Pinwheel::Model::DateBase;
use Pinwheel::Model::Date;

our @ISA = qw(Pinwheel::Model::DateBase);


# Constructors

sub new
{
    my ($class, $s, $utc) = @_;
    $s = CORE::time() unless defined($s);
    my $t = $utc ? [gmtime $s] : [localtime $s];
    return bless({ s => $s, t => $t, u => $utc ? 1 : 0 }, $class);
}

sub now { new Pinwheel::Model::Time(CORE::time(), shift) }
sub utc { new Pinwheel::Model::Time(timegm_nocheck(_make_t(@_)), 1) }
sub local { new Pinwheel::Model::Time(timelocal_nocheck(_make_t(@_)), 0) }
sub now_0seconds
{
    my $t = now(@_);
    $t->{s} -= $t->{t}[0];
    $t->{t}[0] = 0;
    return $t;
}

sub _make_t
{
    ($_[5] || 0, $_[4] || 0, $_[3] || 0, $_[2] || 1, ($_[1] || 1) - 1, $_[0]);
}

sub _pair
{
    $_[0]->{pair} = $_[1];
    return $_[0];
}

sub _derived
{
    my ($self, $y, $m, $d, $hh, $mm, $ss) = @_;
    my $fn = $self->{u} ? \&timegm_nocheck : \&timelocal_nocheck;
    return new Pinwheel::Model::Time(&$fn($ss, $mm, $hh, $d, $m, $y), $self->{u});
}


# Date/time values

sub timestamp { $_[0]->{s} }
sub hour { $_[0]->{t}[2] }
sub min { $_[0]->{t}[1] }
sub sec { $_[0]->{t}[0] }


# Formatting

sub hh_mm
{
    my $t = $_[0]->{t};
    return sprintf('%02d:%02d', $t->[2], $t->[1]);
}

sub hh_mm_ss
{
    my $t = $_[0]->{t};
    return sprintf('%02d:%02d:%02d', $t->[2], $t->[1], $t->[0]);
}

sub rfc822
{
    my $utc = $_[0]->getutc;
    my $t = $utc->{t};
    return sprintf('%s, %02d %s %d %02d:%02d:%02d GMT',
        $utc->short_day_name,
        $t->[3], $utc->short_month_name, $t->[5] + 1900,
        $t->[2], $t->[1], $t->[0]
    );
}

sub iso8601
{
    my $t = $_[0]->{t};
    my $s = sprintf(
        '%d-%02d-%02dT%02d:%02d:%02d',
        $t->[5] + 1900, $t->[4] + 1, $t->[3], $t->[2], $t->[1], $t->[0]
    );
    return $s . ($t->[8] ? '+01:00' : 'Z');
}

sub iso8601_ical
{
    my $t = $_[0]->{t};
    my $s = sprintf(
        '%d%02d%02dT%02d%02d%02d',
        $t->[5] + 1900, $t->[4] + 1, $t->[3], $t->[2], $t->[1], $t->[0]
    );
    $s .= 'Z' unless $t->[8];
    return $s;
}


# Date/time adjustment

sub getutc
{
    my $self = shift;
    return $self if $self->{u};
    return $self->{pair} if ($self->{pair});
    return $self->{pair} = Pinwheel::Model::Time->new($self->{s}, 1)->_pair($self);
}

sub getlocal
{
    my $self = shift;
    return $self unless $self->{u};
    return $self->{pair} if ($self->{pair});
    return $self->{pair} = Pinwheel::Model::Time->new($self->{s}, 0)->_pair($self);
}

sub add
{
    my ($self, $seconds) = @_;
    return new Pinwheel::Model::Time($self->{s} + $seconds, $self->{u});
}


# Type conversion

sub toJson
{
    return $_[0]->timestamp;
}

sub sql_param
{
    return $_[0]->getutc->strftime('%Y-%m-%d %H:%M:%S');
}

sub route_param
{
    return $_[0]->timestamp;
}

sub to_date
{
    Pinwheel::Model::Date::date($_[0]->{t}[5] + 1900, $_[0]->{t}[4] + 1, $_[0]->{t}[3]);
}


1;

__DATA__