File Coverage

blib/lib/Perlbal/Plugin/ExpandSSL.pm

Criterion	Covered	Total	%
statement	58	58	100.0
branch	6	6	100.0
condition	3	3	100.0
subroutine	14	14	100.0
pod	7	7	100.0
total	88	88	100.0

package Perlbal::Plugin::ExpandSSL;

use strict;
use warnings;
use Perlbal;
use Crypt::X509;
use MIME::Base64;
use File::Slurp;

our $VERSION = '0.02';

my %registry = ();
my %headers  = (
    X_FORWARDED_SSL_S_DN_CN => 'subject_cn',
);


sub load {1}

sub register {
    my ( $self, $svc ) = @_;
    $svc->register_hook(
        'ExpandSSL',
        'start_proxy_request',
        sub { expand_ssl(@_) },
    );

    build_registry( $svc->{'ssl_cert_file'} );

    return 1;
}

sub build_registry {
    my $file = shift;
    my @pem  = read_file($file);
    my $pem  = serialize_pem(@pem);
    my $der  = decode_base64($pem);
    my $cert = Crypt::X509->new( cert => $der );

    if ( $cert->error ) {
        my $error = $cert->error;
        warn "ERROR: $error\n";
        return 1;
    }

    foreach my $header ( keys %headers ) {
        my $method = $headers{$header};
        $registry{$header} = $cert->$method;
    }

    return 0;
}

sub serialize_pem {
    my @pem       = @_;
    my $PEM_BEGIN = '-----BEGIN CERTIFICATE-----';
    my $PEM_END   = '-----END CERTIFICATE-----';
    my $pem;

    foreach my $line (@pem) {
        $line =~ s/^\s+//;
        $line =~ s/\s+$//;
        chomp $line;
        $line or next;

        if ( $line eq $PEM_BEGIN or $line eq $PEM_END ) {
            next;
        }

        $pem .= "$line\n";
    }

    return $pem;
}

sub expand_ssl {
    my $svc         = shift;
    my $req_headers = $svc->{'req_headers'};

    foreach my $header ( keys %registry ) {
        $req_headers->header( $header, $registry{$header} );
    }

    return 0;
}

sub unregister {
    # clearing registry
    %registry = ();

    return 1;
}

sub unload {1}

1;

__END__