File Coverage

blib/lib/PerlIO/via/UnPod.pm

Criterion	Covered	Total	%
statement	16	16	100.0
branch	10	10	100.0
condition			n/a
subroutine	4	4	100.0
pod	2	2	100.0
total	32	32	100.0

package PerlIO::via::UnPod;

$VERSION= '0.08';

# be as strict as possible
use strict;

# satisfy -require-
1;

#-------------------------------------------------------------------------------
#
# Standard Perl features
#
#-------------------------------------------------------------------------------
#  IN: 1 class to bless with
#      2 mode string (ignored)
#      3 file handle of PerlIO layer below (ignored)
# OUT: 1 blessed object

sub PUSHED {

    # create object with right attributes
    return bless { insrc => 1 }, $_[0];
} #PUSHED

#-------------------------------------------------------------------------------
#  IN: 1 instantiated object
#      2 handle to read from
# OUT: 1 processed string (if any)

sub FILL {

    # process all lines
    local($_);
    while ( defined( $_= readline( $_[1] ) ) ) {

        # pod, and the end of it
	if ( m#^=[a-zA-Z]# ) {
            $_[0]->{insrc}= m#^=cut#;
        }

        # still in source
        elsif ( $_[0]->{insrc} ) {
            return $_;
        }
    }

    return undef;
} #FILL

#-------------------------------------------------------------------------------
#  IN: 1 instantiated object
#      2 buffer to be written
#      3 handle to write to
# OUT: 1 number of bytes written or -1 to indicate failure

sub WRITE {

    # all lines
    foreach ( split( m#(?<=$/)#, $_[1] ) ) {

        # pod, and the end of it
	if ( m#^=[a-zA-Z]# ) {
            $_[0]->{insrc}= m#^=cut#;
        }

        # still in source
        elsif ( $_[0]->{insrc} ) {
            return -1 if !print {$_[2]} $_;
        }
    }

    return length( $_[1] );
} #WRITE

#-------------------------------------------------------------------------------

__END__