File Coverage

lib/Perl/Critic/MergeProfile.pm

Criterion	Covered	Total	%
statement	66	66	100.0
branch	22	22	100.0
condition	12	12	100.0
subroutine	12	12	100.0
pod	5	5	100.0
total	117	117	100.0

package Perl::Critic::MergeProfile;

use 5.006;
use strict;
use warnings;

our $VERSION = '0.003';

use Carp         ();
use Config::Tiny ();
use Scalar::Util ();

sub new {
    my ($class) = @_;

    my $self = bless {}, $class;

    return $self;
}

sub read {
    my $self = shift;

    my $config = Config::Tiny->read(@_);

    Carp::croak Config::Tiny->errstr() if !defined $config;

    $self->_merge($config);

    return $self;
}

sub read_string {
    my $self = shift;

    my $config = Config::Tiny->read_string(@_);

    Carp::croak Config::Tiny->errstr() if !defined $config;

    $self->_merge($config);

    return $self;
}

sub _merge {
    my ( $self, $config ) = @_;

    if ( !exists $self->{_config} ) {
        $self->{_config} = $config;
        return;
    }

    for my $key ( grep { !m{ ^ - }xsm } keys %{$config} ) {
        Carp::croak "$key is enabled and disabled in the same profile" if exists $config->{"-$key"};
    }

  KEY:
    for my $key ( keys %{$config} ) {
        if ( $key =~ m { ^ - (.+ ) }xsm ) {
            my $policy = $1;
            delete $self->{_config}{$policy};
            $self->{_config}{$key} = {};
            next KEY;
        }

        if ( $key eq '_' ) {
            if ( !exists $self->{_config}{'_'} ) {
                $self->{_config}{'_'} = {};
            }

            %{ $self->{_config}{'_'} } = ( %{ $self->{_config}{'_'} }, %{ $config->{'_'} } );
            next KEY;
        }

        delete $self->{_config}{"-$key"};
        $self->{_config}{$key} = $config->{$key};
    }

    return;
}

sub write {
    my $self = shift;

    Carp::croak 'No policy exists to write' if !exists $self->{_config} || !Scalar::Util::blessed( $self->{_config} ) || !$self->{_config}->isa('Config::Tiny');

    my $rc = $self->{_config}->write(@_);

    Carp::croak Config::Tiny->errstr() if !$rc;

    return $rc;
}

sub write_string {
    my $self = shift;

    Carp::croak 'No policy exists to write' if !exists $self->{_config} || !Scalar::Util::blessed( $self->{_config} ) || !$self->{_config}->isa('Config::Tiny');

    my $string = $self->{_config}->write_string(@_);

    Carp::croak Config::Tiny->errstr() if !defined $string;

    return $string;
}

1;

__END__