File Coverage

blib/lib/Path/Tiny/Archive/Zip.pm

Criterion	Covered	Total	%
statement	38	43	88.3
branch	11	20	55.0
condition			n/a
subroutine	10	10	100.0
pod	2	2	100.0
total	61	75	81.3

package Path::Tiny::Archive::Zip;

# ABSTRACT: Zip/unzip add-on for file path utility

use strict;
use warnings;

use Archive::Zip qw( :ERROR_CODES :CONSTANTS );
use Path::Tiny qw( path );

use namespace::clean;

use Exporter qw( import );


our $VERSION = '0.003';

our %EXPORT_TAGS = ( const =>[qw(
    COMPRESSION_DEFAULT
    COMPRESSION_NONE
    COMPRESSION_FASTEST
    COMPRESSION_BEST
)] );
our @EXPORT_OK = @{ $EXPORT_TAGS{const} };


BEGIN {
    push(@Path::Tiny::ISA, __PACKAGE__);
}

use constant {
    COMPRESSION_DEFAULT => COMPRESSION_LEVEL_DEFAULT,           # 6
    COMPRESSION_NONE    => COMPRESSION_LEVEL_NONE,              # 0
    COMPRESSION_FASTEST => COMPRESSION_LEVEL_FASTEST,           # 1
    COMPRESSION_BEST    => COMPRESSION_LEVEL_BEST_COMPRESSION,  # 9
};



sub zip {
    my ($self, $dest, $level) = @_;

    my $zip = Archive::Zip->new;

    if ($self->is_file) {
        $zip->addFile($self->realpath->stringify(), $self->basename, defined $level ? $level : ());
    }
    elsif ($self->is_dir) {
        $zip->addTree($self->realpath->stringify(), '', undef, defined $level ? $level : ());
    }
    else {
        return;
    }

    $dest = path($dest);

    unless ($zip->writeToFileNamed($dest->realpath->stringify()) == AZ_OK) {
        return;
    }

    return $dest;
}


sub unzip {
    my ($self, $dest) = @_;

    my $zip = Archive::Zip->new();

    unless ($zip->read($self->realpath->stringify()) == AZ_OK) {
        return;
    }

    $dest = path($dest);
    if ($dest->exists) {
        return unless $dest->is_dir;
    }
    else {
        $dest->mkpath() or return;
    }

    unless ($zip->extractTree(undef, $dest->realpath->stringify()) == AZ_OK) {
        return;
    }

    return $dest;
}


1;

__END__