File Coverage

blib/lib/PartialApplication.pm

Criterion	Covered	Total	%
statement	31	31	100.0
branch	8	8	100.0
condition			n/a
subroutine	11	11	100.0
pod	3	3	100.0
total	53	53	100.0

package PartialApplication;
use 5.008001;
use strict;
use warnings;

our $VERSION = "0.04";

use Exporter 'import';
use Carp;

our @EXPORT_OK = qw( partiallyApply partiallyApplyRight partiallyApplyN );

sub partiallyApply {
    my ( $sub, @params ) = @_;

    croak "first parameter needs to be a function ref" unless ref $sub eq "CODE";

    return sub {
        $sub->( @params, @_ );
    };
}

sub partiallyApplyRight {
    my ( $sub, @params ) = @_;

    croak "first parameter needs to be a function ref" unless ref $sub eq "CODE";

    return sub {
        $sub->( @_, @params );
    };
}

sub partiallyApplyN {
    my ( $sub, $bitmap, @partialParams ) = @_;

    croak "first parameter needs to be a function ref" unless ref $sub eq "CODE";

    return sub {
        my ( @callParams ) = @_;

        my @partial = @partialParams;

        my @params = map { $_ ? shift @partial : shift @callParams } @{ $bitmap };

        $sub->( @params, @partial, @callParams );
    }
}

1;
__END__