File Coverage

blib/lib/Parse/JapanesePostalCode.pm

Criterion	Covered	Total	%
statement	59	59	100.0
branch	20	22	90.9
condition	5	9	55.5
subroutine	8	8	100.0
pod	3	3	100.0
total	95	101	94.0

package Parse::JapanesePostalCode;
use strict;
use warnings;
use utf8;
our $VERSION = '0.03';

use Parse::JapanesePostalCode::Row;

sub new {
    my($class, %opts) = @_;

    my $self = bless {
        format => 'ken',
        katakana_h2z => 1,
        alnum_z2h    => 1,
        %opts,
        current_build_town      => '',
        current_build_town_kana => '',
    }, $class;

    if ( ! $self->{fh} && $self->{file} && -f $self->{file}) {
        open $self->{fh}, '<:encoding(cp932)', $self->{file};
    }

    $self;
}

sub fetch_obj {
    my($self, ) = @_;

    my $row = $self->get_line;
    return unless $row;
    my @names = Parse::JapanesePostalCode::Row->columns;
    my %columns;
    @columns{@names} = @{ $row };

    Parse::JapanesePostalCode::Row->new(
        build_town      => $self->{current_build_town},
        build_town_kana => $self->{current_build_town_kana},
        katakana_h2z    => $self->{katakana_h2z},
        alnum_z2h       => $self->{alnum_z2h},
        %columns,
    );
}

sub _get_line {
    my($self, ) = @_;

    my $fh = $self->{fh};
    my $line = <$fh>;
    return unless $line;
    $line =~ s/\r\n$//;

    # easy csv parser for KEN_ALL.csv
    my @row = map {
        my $data = $_;
        $data =~ s/^"//;
        $data =~ s/"$//;
        $data;
    } split ',', $line;

    \@row;
}

sub get_line {
    my($self, ) = @_;

    my $row = $self->_get_line;
    return unless $row;
    if ($row->[8] =~ /（.+[^）]$/) {
        my $past_town_kana = $row->[5];
        while (1) {
            my $tmp = $self->_get_line;
            return unless $tmp;
            $row->[5] .= $tmp->[5] unless $past_town_kana eq $tmp->[5];
            $row->[8] .= $tmp->[8];
            last if $row->[8] =~ /\）$/;
            $past_town_kana = $tmp->[5];
        }
    }

    my $town = $row->[8];

    if ($town =~ /^(.+)（次のビルを除く）$/) {
        $self->{current_build_town} = $1;
        ($self->{current_build_town_kana}) = $row->[5] =~ /^(.+)\(/;
    } elsif ($row->[2] eq '4530002' && $town =~ /^名駅\（/) {
        $self->{current_build_town}      = '名駅';
        $self->{current_build_town_kana} = 'ﾒｲｴｷ';
    } else {
        my $current_build_town = $self->{current_build_town};
        unless ($town =~ /^$current_build_town.+（.+階.*）$/) {
            $self->{current_build_town}      = '';
            $self->{current_build_town_kana} = '';
        }
    }

    $row;
}

1;
__END__