File Coverage

blib/lib/Parse/CommandLine.pm

Criterion	Covered	Total	%
statement	43	52	82.6
branch	19	24	79.1
condition	4	9	44.4
subroutine	5	5	100.0
pod	1	1	100.0
total	72	91	79.1

package Parse::CommandLine;
use 5.008001;
use strict;
use warnings;

our $VERSION = "0.02";

use parent 'Exporter';
our @EXPORT = qw/parse_command_line/;

sub parse_command_line {
    my $str = shift;

    $str =~ s/\A\s+//ms;
    $str =~ s/\s+\z//ms;

    my @argv;
    my $buf;
    my $escaped;
    my $double_quoted;
    my $single_quoted;

    for my $char (split //, $str) {
        if ($escaped) {
            $buf .= $char;
            $escaped = undef;
            next;
        }

        if ($char eq '\\') {
            if ($single_quoted) {
                $buf .= $char;
            }
            else {
                $escaped = 1;
            }
            next;
        }

        if ($char =~ /\s/) {
            if ($single_quoted || $double_quoted) {
                $buf .= $char;
            }
            else {
                push @argv, $buf if defined $buf;
                undef $buf;
            }
            next;
        }

        if ($char eq '"') {
            if ($single_quoted) {
                $buf .= $char;
                next;
            }
            $double_quoted = !$double_quoted;
            next;
        }

        if ($char eq "'") {
            if ($double_quoted) {
                $buf .= $char;
                next;
            }
            $single_quoted = !$single_quoted;
            next;
        }

        $buf .= $char;
    }
    push @argv, $buf if defined $buf;

    if ($escaped || $single_quoted || $double_quoted) {
        die 'invalid command line string';
    }

    @argv;
}

1;
__END__