File Coverage

blib/lib/POE/Filter/JSONMaybeXS.pm

Criterion	Covered	Total	%
statement	33	49	67.3
branch	3	12	25.0
condition	1	3	33.3
subroutine	8	10	80.0
pod	5	5	100.0
total	50	79	63.2

package POE::Filter::JSONMaybeXS;
our $AUTHORITY = 'cpan:GETTY';
# ABSTRACT: A POE filter using JSON::MaybeXS
$POE::Filter::JSONMaybeXS::VERSION = '0.002';
use Carp;
use JSON::MaybeXS;

use strict;
use warnings;

use base qw( POE::Filter );

sub BUFFER () { 0 }
sub OBJ    () { 1 }

sub new {
  my $class = shift;
  croak "$class requires an even number of parameters" if @_ % 2;
  my %opts = @_;
  bless( [
    [],                         # BUFFER
    JSON::MaybeXS->new( %opts ) # OBJ
  ], ref $class || $class );
}

sub get {
  my ($self, $lines) = @_;
  my $ret = [];

  foreach my $json (@$lines) {
    if ( my $data = eval { ($self->[ OBJ ]->decode( $json )) } ) {
      push( @$ret, $data );
    } else {
      warn "Couldn't convert json: $@";
    }
  }
  return $ret;
}

sub get_one_start {
  my ($self, $lines) = @_;
  $lines = [ $lines ] unless ( ref( $lines ) );
  push( @{ $self->[ BUFFER ] }, @{ $lines } );
}

sub get_one {
  my $self = shift;
  my $ret = [];

  if ( my $line = shift ( @{ $self->[ BUFFER ] } ) ) {
    if ( my $data = eval { ($self->[ OBJ ]->decode( $line )) } ) {
      push( @$ret, $data );
    } else {
      warn "Couldn't convert json: $@";
    }
  }

  return $ret;
}

sub put {
  my ($self, $objects) = @_;
  my $ret = [];

  foreach my $obj (@$objects) {
    if ( my $json = eval { $self->[ OBJ ]->encode( $obj ) } ) {
      push( @$ret, $json );
    } else {
      warn "Couldn't convert object to json\n";
    }
  }

  return $ret;
}

1;

__END__