File Coverage

blib/lib/POE/Filter/CSV_XS.pm

Criterion	Covered	Total	%
statement	33	45	73.3
branch	3	10	30.0
condition			n/a
subroutine	7	9	77.7
pod	5	5	100.0
total	48	69	69.5

# Author Chris "BinGOs" Williams
#
# This module may be used, modified, and distributed under the same
# terms as Perl itself. Please see the license that came with your Perl
# distribution for details.
#

package POE::Filter::CSV_XS;
$POE::Filter::CSV_XS::VERSION = '1.18';
#ABSTRACT: A POE-based parser for CSV based files.

use strict;
use warnings;
use Text::CSV_XS;
use base qw(POE::Filter);

sub new {
  my $class = shift;
  my %opts = @_;
  $opts{lc $_} = delete $opts{$_} for keys %opts;
  delete $opts{eol};
  my $self = {};
  $self->{BUFFER} = [];
  $self->{csv_filter} = Text::CSV_XS->new( \%opts );
  bless $self, $class;
}

sub get {
  my ($self, $raw) = @_;
  my $events = [];

  foreach my $event ( @$raw ) {
    my $status = $self->{csv_filter}->parse($event);
    push @$events, [ $self->{csv_filter}->fields() ] if $status;
  }
  return $events;
}

sub get_one_start {
  my ($self, $raw) = @_;
  push @{ $self->{BUFFER} }, $_ for @$raw;
}

sub get_one {
  my $self = shift;
  my $events = [];

  my $event = shift @{ $self->{BUFFER} };
  if ( defined $event ) {
    my $status = $self->{csv_filter}->parse($event);
    push @$events, [ $self->{csv_filter}->fields() ] if $status;
  }
  return $events;
}

sub put {
  my ($self,$events) = @_;
  my $raw_lines = [];

  foreach my $event ( @$events ) {
    if ( ref $event eq 'ARRAY' ) {
      my $status = $self->{csv_filter}->combine(@$event);
      push @$raw_lines, $self->{csv_filter}->string() if $status;

    }
    else {
	warn "non arrayref passed to put()\n";
    }
  }
  return $raw_lines;
}

qq[let,us,csv,xs];

__END__