File Coverage

blib/lib/POE/Filter/CSV.pm

Criterion	Covered	Total	%
statement	36	48	75.0
branch	3	10	30.0
condition			n/a
subroutine	8	10	80.0
pod	6	6	100.0
total	53	74	71.6

# Author Chris "BinGOs" Williams
#
# This module may be used, modified, and distributed under the same
# terms as Perl itself. Please see the license that came with your Perl
# distribution for details.
#

package POE::Filter::CSV;
$POE::Filter::CSV::VERSION = '1.18';
#ABSTRACT: A POE-based parser for CSV based files.

use strict;
use warnings;
use Text::CSV;
use base qw(POE::Filter);

sub new {
  my $class = shift;
  my $self = {};
  $self->{BUFFER} = [];
  $self->{csv_filter} = Text::CSV->new(@_);
  bless $self, $class;
}

sub get {
  my ($self, $raw) = @_;
  my $events = [];

  foreach my $event ( @$raw ) {
    my $status = $self->{csv_filter}->parse($event);
    push @$events, [ $self->{csv_filter}->fields() ] if $status;
  }
  return $events;
}

sub get_one_start {
  my ($self, $raw) = @_;
  push @{ $self->{BUFFER} }, $_ for @$raw;
}

sub get_one {
  my $self = shift;
  my $events = [];

  my $event = shift @{ $self->{BUFFER} };
  if ( defined $event ) {
    my $status = $self->{csv_filter}->parse($event);
    push @$events, [ $self->{csv_filter}->fields() ] if $status;
  }
  return $events;
}

sub put {
  my ($self,$events) = @_;
  my $raw_lines = [];

  foreach my $event ( @$events ) {
    if ( ref $event eq 'ARRAY' ) {
      my $status = $self->{csv_filter}->combine(@$event);
      push @$raw_lines, $self->{csv_filter}->string() if $status;

    }
    else {
	warn "non arrayref passed to put()\n";
    }
  }
  return $raw_lines;
}

sub clone {
  my $self = shift;
  my $nself = { };
  $nself->{$_} = $self->{$_} for keys %{ $self };
  $nself->{BUFFER} = [ ];
  return bless $nself, ref $self;
}

qq[let,us,csv];

__END__