File Coverage

blib/lib/POE/Component/IRC/Plugin/WWW/Reddit/TIL.pm

Criterion	Covered	Total	%
statement	30	48	62.5
branch	2	6	33.3
condition	1	6	16.6
subroutine	8	11	72.7
pod	0	4	0.0
total	41	75	54.6

package POE::Component::IRC::Plugin::WWW::Reddit::TIL;

use 5.010;
use strict;
use warnings;

our $VERSION = '0.07';

use POE::Component::IRC::Plugin qw( :ALL );
use Mojo::UserAgent;
use WWW::Shorten::Simple;

sub new {
    my $package = shift;
    return bless {}, $package;
}

sub PCI_register {
    my ($self, $irc) = splice @_, 0, 2;

    $irc->plugin_register($self, 'SERVER', qw(public));
    return 1;
}

# This is method is mandatory but we don't actually have anything to do.
sub PCI_unregister {
    return 1;
}

sub S_public {
    my ($self, $irc) = splice @_, 0, 2;

    # Parameters are passed as scalar-refs including arrayrefs.
    my $nick    = (split /!/, ${$_[0]})[0];
    my $channel = ${$_[1]}->[0];
    my $msg     = ${$_[2]};

    my $reply = $msg =~ /^!til\b/i && $self->_get_TIL;

    if ($reply) {
        $irc->yield(privmsg => $channel => "$nick: $reply");
        return PCI_EAT_PLUGIN;
    }

    # Default action is to allow other plugins to process it.
    return PCI_EAT_NONE;
}

sub _get_TIL {
    my $ua = Mojo::UserAgent->new;
    my %posts;
    foreach my $post (
        @{$ua->get('http://www.reddit.com/r/todayilearned.json')->res->json->{data}{children}})
    {
        my $title = $post->{data}{title};
        my $link  = $post->{data}{url};
        $posts{$title} = $link if $title && $link;
    }
    return unless %posts;

    my $title = (keys %posts)[rand keys %posts];
    my $short =
      WWW::Shorten::Simple->new('Bitly', 'aggrolite', 'R_418414782c81e2c4444348e367201706');
    my $link = $short->shorten($posts{$title});
    return "$title $link";
}

1;

__END__