File Coverage

blib/lib/POE/Component/WWW/Google/PageRank.pm

Criterion	Covered	Total	%
statement	74	112	66.0
branch	18	48	37.5
condition			n/a
subroutine	14	18	77.7
pod	3	4	75.0
total	109	182	59.8

package POE::Component::WWW::Google::PageRank;

use strict;
use warnings;

our $VERSION = '1.001004'; # VERSION

use POE (qw( Wheel::Run  Filter::Reference  Filter::Line ));
use Carp;
use WWW::Google::PageRank;

sub spawn {
    my $package = shift;

    croak "$package requires an even number of arguments"
        if @_ & 1;

    my %params = @_;

    $params{ lc $_ } = delete $params{ $_ } for keys %params;

    delete $params{options}
        unless ref $params{options} eq 'HASH';

    my $self = bless \%params, $package;

    $self->{session_id} = POE::Session->create(
        object_states => [
            $self => {
                rank     => '_rank',
                shutdown => '_shutdown',
            },
            $self => [
                qw(
                    _start
                    _child_error
                    _child_closed
                    _child_stderr
                    _child_stdout
                    _sig_chld
                )
            ],
        ],
        ( defined $params{options} ? ( options => $params{options} ) : () )
    )->ID;

    return $self;
}

sub _start {
    my ( $kernel, $self ) = @_[ KERNEL, OBJECT ];
    $self->{session_id} = $_[SESSION]->ID();

    if ( $self->{alias} ) {
        $kernel->alias_set( $self->{alias} );
    }
    else {
        $kernel->refcount_increment( $self->{session_id} => __PACKAGE__ );
    }

    $self->{wheel} = POE::Wheel::Run->new(
        Program => \&_rank_wheel,
        ErrorEvent => '_child_error',
        CloseEvent => '_child_closed',
        StderrEvent => '_child_stderr',
        StdoutEvent => '_child_stdout',
        StdioFilter => POE::Filter::Reference->new,
        StderrFilter => POE::Filter::Line->new,
        ( $^O eq 'MSWin32' ? ( CloseOnCall => 0 ) : ( CloseOnCall => 1 ) ),
    );

    $kernel->yield('shutdown')
        unless $self->{wheel};

    $kernel->sig_child( $self->{wheel}->PID, '_sig_chld' );

    undef;
}

sub _sig_chld {
    $poe_kernel->sig_handled;
}

sub session_id {
    return $_[0]->{session_id};
}

sub rank {
    my $self = shift;
    $poe_kernel->post( $self->{session_id} => 'rank' => @_ );
}

sub _rank {
    my ( $kernel, $self ) = @_[ KERNEL, OBJECT ];
    my $sender = $_[SENDER]->ID;

    return
        if $self->{shutdown};

    my $args;

    if ( ref $_[ARG0] eq 'HASH' ) {
        $args = { %{ $_[ARG0] } };
    }
    else {
        warn "First parameter must be a hashref... trying to adjust";
        $args = { @_[ARG0 .. $#_] };
    }

    $args->{ lc $_ } = delete $args->{ $_ }
        for grep { !/^_/ } keys %{ $args };

    unless ( $args->{event} ) {
        warn "No `event` parameter was specified";
        return;
    }

    unless ( $args->{page} ) {
        warn "No `page` parameter was specified";
        return;
    }

    # not sure if this is mandatory but WWW::Google:PageRank rejects URIs
    # not matching this regex, so we'll fix it up and hope it won't
    # eat us
    unless ( $args->{page} =~ m#^https?://#i ) {
        warn "Parameter `page` does not match m#^https?://#i"
            if $self->{debug};

        $args->{page} = "http://$args->{page}";
    }

    if ( $args->{session} ) {
        if ( my $ref = $kernel->alias_resolve( $args->{session} ) ) {
            $args->{sender} = $ref->ID;
        }
        else {
            warn "Parameter `session` did not resolve to an active POE"
                    . " session, aborting";
            return;
        }
    }
    else {
        $args->{sender} = $sender;
    }

    $kernel->refcount_increment( $args->{sender} => __PACKAGE__ );
    $self->{wheel}->put( $args );

    undef;
}

sub shutdown {
    my $self = shift;
    $poe_kernel->post( $self->{session_id} => 'shutdown' => @_ );
}

sub _shutdown {
    my ( $kernel, $self ) = @_[ KERNEL, OBJECT ];
    $kernel->alarm_remove_all;
    $kernel->alias_remove( $_ ) for $kernel->alias_list;
    $kernel->refcount_decrement( $self->{session_id} => __PACKAGE__ )
        unless $self->{alias};

    $self->{shutdown} = 1;
    $self->{wheel}->shutdown_stdin
        if $self->{wheel};

    undef;
}
sub _child_closed {
    my ( $kernel, $self ) = @_[ KERNEL, OBJECT ];

    warn "Got _child_closed() (@_[ARG0..$#_])"
        if $self->{debug};

    delete $self->{wheel};
    $kernel->yield('shutdown')
        unless $self->{shutdown};

    undef;
}

sub _child_error {
    my ( $kernel, $self ) = @_[ KERNEL, OBJECT ];

    warn "Got _child_error() (@_[ARG0..$#_])"
        if $self->{debug};

    delete $self->{wheel};
    $kernel->yield('shutdown')
        unless $self->{shutdown};

    undef;
}

sub _child_stderr {
    my ( $kernel, $self, $input ) = @_[ KERNEL, OBJECT, ARG0 ];
    warn "Got _child_stderr: $input\n"
        if $self->{debug};

    undef;
}

sub _child_stdout {
    my ( $kernel, $self, $input ) = @_[ KERNEL, OBJECT, ARG0 ];

    my $session = delete $input->{sender};
    my $event   = delete $input->{event};

    $kernel->post( $session => $event => $input );
    $kernel->refcount_decrement( $session => __PACKAGE__ );

    undef;
}

sub _rank_wheel {
    if ( $^O eq 'MSWin32' ) {
        binmode STDIN;
        binmode STDOUT;
    }

    my $raw;
    my $size = 4096;
    my $filter = POE::Filter::Reference->new;

    while ( sysread STDIN, $raw, $size ) {
        my $requests = $filter->get( [ $raw ] );
        foreach my $req ( @$requests ) {
            my $page_rank
                = WWW::Google::PageRank->new( %{ $req->{options} || {} } );

            @{ $req }{ qw(rank response) }
                = $page_rank->get( $req->{page} );

            unless ( $req->{response}->is_success ) {
                @{ $req }{ qw(rank error) }
                    = ( undef, $req->{response}->status_line );
            }

            my $response = $filter->put( [ $req ] );
            print STDOUT @$response;
        }
    }
}

1;
__END__