File Coverage

blib/lib/PDL/NDBin/Iterator.pm

Criterion	Covered	Total	%
statement	67	68	98.5
branch	7	8	87.5
condition			n/a
subroutine	24	24	100.0
pod	13	13	100.0
total	111	113	98.2

package PDL::NDBin::Iterator;
# ABSTRACT: Iterator object for PDL::NDBin
$PDL::NDBin::Iterator::VERSION = '0.019';
use strict;
use warnings;
use Carp;
use List::Util qw( reduce );
use List::MoreUtils qw( all );
use XSLoader;
use Params::Validate qw( validate ARRAYREF );



sub new
{
	my $class = shift;
	my %params = validate( @_, {
			bins  => {
				type      => ARRAYREF,
				callbacks => { 'have at least one bin along every dimension' => sub { my $bins = shift; all { $_ > 0 } @$bins } },
			},
			array => {
				type      => ARRAYREF,
				callbacks => { 'have at least one element' => sub { my $array = shift; @$array } },
			},
			idx   => { can  => [ qw( eq which ) ] },
		} );
	my $self = {
		bins   => $params{bins},
		array  => $params{array},
		idx    => $params{idx},
		active => [ (1) x @{ $params{array} } ],
		bin    => 0,
		var    => -1,
		nbins  => (reduce { $a * $b } @{ $params{bins} }),
		nvars  => (scalar @{ $params{array} }),
	};
	return bless $self, $class;
}


# advance() is implemented in XS


sub bin   { $_[0]->{bin} }
sub var   { $_[0]->{var} }
sub done  { $_[0]->{bin} >= $_[0]->{nbins} }
sub bins  { @{ $_[0]->{bins} } }
sub nbins { $_[0]->{nbins} }
sub nvars { $_[0]->{nvars} }
sub data  { $_[0]->{array}->[ $_[0]->{var} ] }
sub idx   { $_[0]->{idx} }


sub var_active
{
	my $self = shift;
	my $i = $self->{var};
	if( @_ ) { $self->{active}->[ $i ] = shift }
	else { $self->{active}->[ $i ] }
}


sub want
{
	my $self = shift;
	unless( defined $self->{want} ) {
		$self->{want} = PDL::which $self->idx == $self->{bin};
	}
	return $self->{want};
}


sub selection
{
	my $self = shift;
	unless( defined $self->{selection} ) {
		$self->{selection} = $self->data->index( $self->want );
	}
	return $self->{selection};
}


sub unflatten
{
	my $self = shift;
	unless( defined $self->{unflattened} ) {
		my $q = $self->{bin}; # quotient
		$self->{unflattened} =
			[ map {
				( $q, my $r ) = do { use integer; ( $q / $_, $q % $_ ) };
				$r
			      } $self->bins
			];
	}
	return @{ $self->{unflattened} };
}

XSLoader::load( __PACKAGE__ );

1;

__END__