File Coverage

blib/lib/PDF/API2/Resource/XObject/Form/BarCode/qrcode.pm

Criterion	Covered	Total	%
statement	12	45	26.6
branch	0	10	0.0
condition	0	8	0.0
subroutine	4	6	66.6
pod	2	2	100.0
total	18	71	25.3

package PDF::API2::Resource::XObject::Form::BarCode::qrcode;

use base 'PDF::API2::Resource::XObject::Form::BarCode';

use strict;
use warnings;

our $VERSION = '2.045'; # VERSION

use Carp;

our @CARP_NOT = qw(PDF::API2);

sub new {
    my ($class, $pdf, %options) = @_;
    my $self = $class->SUPER::new($pdf, %options);

    eval {
        require Text::QRCode;
    };
    if ($@) {
        croak "Error loading Text::QRCode: $@";
    }

    my $mode = $options{'mode'} // '8-bit';
    $mode = 'numerical'       if $mode eq 'numeric';
    $mode = 'alpha-numerical' if $mode eq 'alphanumeric';
    $mode = 'alpha-numerical' if $mode eq 'alpha-numeric';

    my $generator = Text::QRCode->new(
        level         => ($options{'error_correction'} // 'L'),
        version       => ($options{'version'}          // 0),
        mode          => $mode,
        casesensitive => ($options{'case_sensitive'}   // 1),
    );

    my $lines_ref = $generator->plot($options{'code'});
    my @lines = reverse map { join('', @$_) } @$lines_ref;

    $self->render(@lines);
    return $self;
}

sub render {
    my ($self, @lines) = @_;

    $self->fillcolor($self->{' color'});

    my $y = $self->{' quzn'};
    my $w = $self->{' mils'} / 1000 * 72;
    my $h = $self->{' zone'};
    foreach my $line (@lines) {
        my $x = $self->{' quzn'};
        foreach my $char (split m//, $line) {
            if ($char eq '*') {
                $self->rectangle($x, $y, $x + $w, $y + $h);
                $self->fill();
            }
            $x += $w;
        }
        $y += $h;
    }

    $self->{' w'} = 2 * $self->{' quzn'} + length($lines[0]) * $w;
    $self->{' h'} = 2 * $self->{' quzn'} + length($lines[0]) * $h;
    $self->bbox(0, 0, $self->{' w'}, $self->{' h'});

    return $self;
}

1;

__END__