File Coverage

inc/Test/Requires.pm

Criterion	Covered	Total	%
statement	42	58	72.4
branch	8	20	40.0
condition	3	14	21.4
subroutine	10	10	100.0
pod	0	1	0.0
total	63	103	61.1

#line 1
package Test::Requires;
use strict;
use warnings;
our $VERSION = '0.07';
use base 'Test::Builder::Module';
use 5.006000;

sub import {
    my $class = shift;
    my $caller = caller(0);

    # export methods
    {
        no strict 'refs';
        *{"$caller\::test_requires"} = \&test_requires;
    }

    # test arguments
    if (@_ == 1 && ref $_[0] && ref $_[0] eq 'HASH') {
        while (my ($mod, $ver) = each %{$_[0]}) {
            test_requires($mod, $ver, $caller);
        }
    } else {
        for my $mod (@_) {
            test_requires($mod, undef, $caller);
        }
    }
}

sub test_requires {
    my ( $mod, $ver, $caller ) = @_;
    return if $mod eq __PACKAGE__;
    if (@_ != 3) {
        $caller = caller(0);
    }
    $ver ||= '';

    eval qq{package $caller; use $mod $ver}; ## no critic.
    if (my $e = $@) {
        my $skip_all = sub {
            my $builder = __PACKAGE__->builder;

            if (not defined $builder->has_plan) {
                $builder->skip_all(@_);
            } elsif ($builder->has_plan eq 'no_plan') {
                $builder->skip(@_);
                if ( $builder->can('parent') && $builder->parent ) {
                    die bless {} => 'Test::Builder::Exception';
                }
                exit 0;
            } else {
                for (1..$builder->has_plan) {
                    $builder->skip(@_);
                }
                if ( $builder->can('parent') && $builder->parent ) {
                    die bless {} => 'Test::Builder::Exception';
                }
                exit 0;
            }
        };

        my $msg = "$e";
        if ( $e =~ /^Can't locate/ ) {
            $msg = "Test requires module '$mod' but it's not found";
        }

        if ($ENV{RELEASE_TESTING}) {
            __PACKAGE__->builder->BAIL_OUT($msg);
        }
        else {
            $skip_all->($msg);
        }
    }
}

1;
__END__