File Coverage

blib/lib/OPM/Maker/Command/bashcompletion.pm

Criterion	Covered	Total	%
statement	15	56	26.7
branch	0	12	0.0
condition	0	2	0.0
subroutine	5	11	45.4
pod	4	4	100.0
total	24	85	28.2

package OPM::Maker::Command::bashcompletion;
$OPM::Maker::Command::bashcompletion::VERSION = '1.17';
use strict;
use warnings;

# ABSTRACT: build bash completion script

use Carp qw(croak);
use Path::Class;

use OPM::Maker -command;

sub abstract {
    return "create bash completion script and enable it for the user";
}

sub opt_spec {
    return ();
}

sub usage_desc {
    return "opmbuild bashcompletion";
}

sub execute {
    my ($self, $opt, $args) = @_;

    my $app = $self->app;

    my %commands = map {
        my ($short) = (split /::/, $_)[-1];
        $short => $_;
    } grep {
        $_ =~ m{\AOPM::Maker::Command};
    } $app->command_plugins;

    my %completion_data;

    CMD:
    for my $cmd ( sort keys %commands ) {
        my $module = $commands{$cmd};

        my @opts = map {
            my $opt_spec = $_->[0] // '';
            my $opt_name = ( split /=/, $opt_spec )[0];
            $opt_name ? '--' . $opt_name : ();
        } $module->opt_spec;

        $completion_data{$cmd} = \@opts;
    }

    my $bash_completion = $self->_bash_completion( %completion_data );
    $self->_create_bash_completion_files( $bash_completion );
}

sub _create_bash_completion_files {
    my ($self, $content) = @_;

    my $base = dir( $ENV{HOME} );
    my $completion = $base->file( '.bash_completion' );
    if ( !-f $completion->stringify ) {
        my $completion_content = q!
for bcfile in ~/.bash_completion.d/* ; do
  . $bcfile
done
        !;

        $completion->spew( $completion_content );
    }

    my $dir = $base->subdir( '.bash_completion.d' );
    if ( !-d $dir->stringify ) {
        $dir->mkpath;
    }

    my $opmbuild_completion = $dir->file('opmbuild');
    $opmbuild_completion->spew( $content );
}

sub _bash_completion {
    my ($self, %data) = @_;

    my $subcommands = join ' ', sort keys %data;

    my @subcommand_data;

    CMD:
    for my $cmd ( sort keys %data ) {
        next CMD if !@{ $data{$cmd} || [] };

        my $case = sprintf q~        %s)
            local %s_opts="%s"
            COMPREPLY=( $(compgen -W "${%s_opts}" -- ${cur}) )
            return 0
            ;;~,
            $cmd,
            $cmd,
            ( join ' ', @{ $data{$cmd} || [] } ),
            $cmd
        ;

        push @subcommand_data, $case;
    }

    my $subcommand_opts = join "\n", @subcommand_data;

    my $completion_script = sprintf q~
_opmbuild()
{
    local cur prev opts base

    COMPREPLY=()
    cur="${COMP_WORDS[COMP_CWORD]}"
    prev="${COMP_WORDS[COMP_CWORD-1]}"

    opts="%s"

    case "${prev}" in
        opmbuild)
            ;;
%s
        *)
            compopt -o nospace
            COMPREPLY=( $( compgen -d -f -- $cur ) )
            return 0
            ;;
    esac

    COMPREPLY=( $(compgen -W "${opts}" -- ${cur}) )
    return 0;
}

complete -F _opmbuild opmbuild
    ~,
        $subcommands,
        $subcommand_opts
    ;
}

1;

__END__