File Coverage

blib/lib/Number/Extreme.pm

Criterion	Covered	Total	%
statement	28	36	77.7
branch	3	4	75.0
condition	3	3	100.0
subroutine	12	17	70.5
pod	5	8	62.5
total	51	68	75.0

package Number::Extreme;

use strict;
use 5.008_001;
our $VERSION = '0.29';

use overload
    '"0+"' => sub { $_[0]{current_value} },
    '""'   => sub { $_[0]{current_value} },
    fallback => 1;

sub new {
    my ($class, %args) = @_;
    bless \%args, __PACKAGE__;
}

sub max {
    my $class     = shift;
    my $extractor = shift;

    return $class->new(
        cmp           => sub { $_[1] > $_[0] },
        extractor     => $extractor,
        current_value => undef,
        current       => undef,
    );
}

sub min {
    my $class     = shift;
    my $extractor = shift;

    return $class->new(
        cmp           => sub { $_[1] < $_[0] },
        extractor     => $extractor,
        current_value => undef,
        current       => undef,
        @_,
    );
}

sub amax {
    my ($class, $array) = @_;
    $class->max(sub { $array->[$_] });
}

sub amin {
    my ($class, $array) = @_;
    $class->min(sub { $array->[$_] });
}

sub test {
    my ($self, $object) = @_;
    local $_ = $object;
    my $value = $self->{extractor} ? $self->{extractor}->() : $_;

    if (!defined $self->{current_value} ||
        $self->{cmp}->($self->{current_value}, $value)) {
        $self->{current} = $_;
        $self->{current_value} = $value;
        return 1;
    }
}

sub current_value { $_[0]->{current_value} }
sub current       { $_[0]->{current} }

1;
__END__