File Coverage

blib/lib/No/Worries/String.pm

Criterion	Covered	Total	%
statement	33	105	31.4
branch	10	48	20.8
condition	0	10	0.0
subroutine	8	13	61.5
pod	6	6	100.0
total	57	182	31.3

#+##############################################################################
#                                                                              #
# File: No/Worries/String.pm                                                   #
#                                                                              #
# Description: string handling without worries                                 #
#                                                                              #
#-##############################################################################

#
# module definition
#

package No::Worries::String;
use strict;
use warnings;
our $VERSION  = "1.5";
our $REVISION = sprintf("%d.%02d", q$Revision: 1.13 $ =~ /(\d+)\.(\d+)/);

#
# used modules
#

use No::Worries::Export qw(export_control);
use Params::Validate qw(validate validate_pos :types);

#
# global variables
#

our(
    @_ByteSuffix,  # byte suffixes used by bytefmt
    @_Map,         # mapping of characters to escaped strings
    %_Plural,      # pluralization cache
);

#
# format a number of bytes
#

sub string_bytefmt ($;$) {
    my($number, $precision) = @_;
    my($index);

    $precision = 2 unless defined($precision);
    $index = 0;
    while ($_ByteSuffix[$index] and $number > 1024) {
        $index++;
        $number /= 1024.0;
    }
    return("$number $_ByteSuffix[$index]") if $number =~ /^\d+$/;
    return(sprintf("%.${precision}f %s", $number, $_ByteSuffix[$index]));
}

#
# escape a string (quite compact, human friendly but not Perl eval()'able)
#

sub string_escape ($) {
    my($string) = @_;
    my(@list);

    validate_pos(@_, { type => SCALAR });
    foreach my $ord (map(ord($_), split(//, $string))) {
        push(@list, $ord < 256 ? $_Map[$ord] : sprintf("\\x{%04x}", $ord));
    }
    return(join("", @list));
}

#
# return the plural form of the given noun
#

sub string_plural ($) {
    my($noun) = @_;

    unless ($_Plural{$noun}) {
        if ($noun =~ /(ch|s|sh|x|z)$/) {
            $_Plural{$noun} = $noun . "es";
        } elsif ($noun =~ /[bcdfghjklmnpqrstvwxz]y$/) {
            $_Plural{$noun} = substr($noun, 0, -1) . "ies";
        } elsif ($noun =~ /f$/) {
            $_Plural{$noun} = substr($noun, 0, -1) . "ves";
        } elsif ($noun =~ /fe$/) {
            $_Plural{$noun} = substr($noun, 0, -2) . "ves";
        } elsif ($noun =~ /[bcdfghjklmnpqrstvwxz]o$/) {
            $_Plural{$noun} = $noun . "es";
        } else {
            $_Plural{$noun} = $noun . "s";
        }
    }
    return($_Plural{$noun});
}

#
# quantify the given (count, noun) pair
#

sub string_quantify ($$) {
    my($count, $noun) = @_;

    return($count . " " . ($count == 1 ? $noun : string_plural($noun)));
}

#
# return the real length of a string (removing ANSI Escape sequences)
#

sub _strlen ($) {
    my($string) = @_;

    return(0) unless defined($string);
    $string =~ s/\x1b\[[0-9;]*[mGKH]//g;
    return(length($string));
}

#
# return an aligned and padded string
#

sub _strpad ($$$) {
    my($string, $length, $align) = @_;
    my($strlen, $before, $after);

    $string = "" unless defined($string);
    $strlen = _strlen($string);
    $align ||= "left";
    if ($align eq "left") {
        $before = 0;
        $after = $length - $strlen;
    } elsif ($align eq "right") {
        $before = $length - $strlen;
        $after = 0;
    } elsif ($align eq "center") {
        $before = ($length - $strlen) >> 1;
        $after = $length - $strlen - $before;
    } else {
        die("unexpected alignment: $align\n");
    }
    return((" " x $before) . $string . (" " x $after));
}

#
# transform a table into a string
#

my %string_table_options = (
    align   => { optional => 1, type => ARRAYREF },
    colsep  => { optional => 1, type => SCALAR },
    header  => { optional => 1, type => ARRAYREF },
    headsep => { optional => 1, type => SCALAR },
    indent  => { optional => 1, type => SCALAR },
);

sub string_table ($@) {
    my($lines, %option, @collen, $index, $length, $result);

    # handle options
    $lines = shift(@_);
    %option = validate(@_, \%string_table_options) if @_;
    $option{align} ||= [];
    $option{colsep} = " | " unless defined($option{colsep});
    $option{headsep} = "=" unless defined($option{headsep});
    $option{indent} = "" unless defined($option{indent});
    # compute column lengths
    foreach my $line ($option{header} ? ($option{header}) : (), @{ $lines }) {
        $index = 0;
        foreach my $entry (@{ $line }) {
            $length = _strlen($entry);
            $collen[$index] = $length
                unless defined($collen[$index]) and $collen[$index] >= $length;
            $index++;
        }
    }
    # compute total length
    $length = length($option{colsep}) * (@collen - 1);
    foreach my $collen (@collen) {
        $length += $collen;
    }
    $result = "";
    # format header
    if ($option{header}) {
        $result .= $option{indent};
        $index = 0;
        while ($index < @collen) {
            $result .= $option{colsep} if $index;
            $result .= _strpad($option{header}[$index],
                               $collen[$index], $option{align}[$index]);
            $index++;
        }
        $result .= "\n";
        $result .= $option{indent};
        $result .= substr($option{headsep} x $length, 0, $length) . "\n";
    }
    # format lines
    foreach my $line (@{ $lines }) {
        $result .= $option{indent};
        $index = 0;
        while ($index < @collen) {
            $result .= $option{colsep} if $index;
            $result .= _strpad($line->[$index],
                               $collen[$index], $option{align}[$index]);
            $index++;
        }
        $result .= "\n";
    }
    return($result);
}

#
# remove leading and trailing spaces
#

sub string_trim ($) {
    my($string) = @_;

    validate_pos(@_, { type => SCALAR });
    $string =~ s/^\s+//;
    $string =~ s/\s+$//;
    return($string);
}

#
# module initialization
#

@_ByteSuffix = qw(B kB MB GB TB PB EB ZB YB);
foreach my $ord (0 .. 255) {
    $_Map[$ord] = 32 <= $ord && $ord < 127 ?
        chr($ord) : sprintf("\\x%02x", $ord);
}
$_Map[ord("\t")] = "\\t";
$_Map[ord("\n")] = "\\n";
$_Map[ord("\r")] = "\\r";
$_Map[ord("\e")] = "\\e";
$_Map[ord("\\")] = "\\\\";
%_Plural = (
    "child" => "children",
    "data"  => "data",
    "foot"  => "feet",
    "index" => "indices",
    "man"   => "men",
    "tooth" => "teeth",
    "woman" => "women",
);

#
# export control
#

sub import : method {
    my($pkg, %exported);

    $pkg = shift(@_);
    grep($exported{$_}++, map("string_$_",
        qw(bytefmt escape plural quantify table trim)));
    export_control(scalar(caller()), $pkg, \%exported, @_);
}

1;

__DATA__