File Coverage

blib/lib/NewFangle/Transaction.pm

Criterion	Covered	Total	%
statement	26	44	59.0
branch	0	8	0.0
condition	0	3	0.0
subroutine	9	12	75.0
pod			n/a
total	35	67	52.2

package NewFangle::Transaction 0.0901 {

  use strict;
  use warnings;
  use 5.014;
  use NewFangle::FFI;
  use NewFangle::Segment;
  use FFI::Platypus::Memory ();
  use Ref::Util qw( is_blessed_ref );
  use JSON::MaybeXS ();
  use Carp ();

# ABSTRACT: NewRelic application class


  sub _segment
  {
    my $xsub = shift;
    my $txn = shift;
    my $seg = $xsub->($txn, @_);
    $seg->{txn} = $txn;
    $seg;
  }

  $ffi->attach( start_segment           => ['newrelic_txn_t','string','string'] => 'newrelic_segment_t' => \&_segment );
  $ffi->attach( start_datastore_segment => ['newrelic_txn_t','string[7]']       => 'newrelic_segment_t' => \&_segment );
  $ffi->attach( start_external_segment  => ['newrelic_txn_t','string[3]']       => 'newrelic_segment_t' => \&_segment );


  $ffi->attach( "add_attribute_$_" => ['newrelic_txn_t','string',$_] => 'bool' )
    for qw( int long double string );


  $ffi->attach( notice_error => [ 'newrelic_txn_t', 'int', 'string', 'string' ] );


  if($ffi->find_symbol('notice_error_with_stacktrace'))
  {
    $ffi->attach( notice_error_with_stacktrace => [ 'newrelic_txn_t', 'int', 'string', 'string', 'string' ] => sub {
      my($xsub, $self, $priority, $errmsg, $errorclass, $errstacktrace) = @_;
      $errstacktrace = [split /\n/, $errstacktrace] unless ref $errstacktrace eq 'ARRAY';
      $errstacktrace = JSON::MaybeXS::encode_json($errstacktrace);
      $xsub->($self, $priority, $errmsg, $errorclass, $errstacktrace);
    });
  }
  else
  {
    *notice_error_with_stacktrace = \¬ice_error;
  }


  $ffi->attach( [ 'ignore_transaction' => 'ignore' ] => ['newrelic_txn_t'] => 'bool' );


  $ffi->attach( [ end_transaction => 'end' ] => ['opaque*'] => 'bool' );


 $ffi->attach( record_custom_event => [ 'newrelic_txn_t', 'opaque*' ] => sub {
   my($xsub, $self, $event) = @_;
   Carp::croak("event must be a NewFangle::CustomEvent")
     unless ref $event eq 'NewFangle::CustomEvent';
   $xsub->($self, $event);
   1;
 });


  $ffi->attach( record_custom_metric => [ 'newrelic_txn_t', 'string', 'double' ] => 'bool' );


  $ffi->attach( [ set_transaction_name => 'set_name' ] => [ 'newrelic_txn_t', 'string' ] => 'bool' );


  $ffi->attach_cast(_ptr_to_string => 'opaque', 'string');
  sub _create_dt_payload {
    my($xsub, $self, $seg) = @_;
    my $seg_ptr;
    if(defined $seg)
    {
      if(is_blessed_ref($seg) && $seg->isa('NewFangle::Segment'))
      {
        $seg_ptr = $seg->{ptr};
      }
      else
      {
        Carp::croak("$seg is not a NewFangle::Segment");
      }
    }
    my $str_ptr = $xsub->($self, $seg_ptr);
    defined $str_ptr
      ? do {
        my $str = _ptr_to_string($str_ptr);
        FFI::Platypus::Memory::free($str_ptr);
        $str;
      } : ();
  }

  $ffi->attach( create_distributed_trace_payload          => [ 'newrelic_txn_t', 'opaque' ] => 'opaque' => \&_create_dt_payload);
  $ffi->attach( create_distributed_trace_payload_httpsafe => [ 'newrelic_txn_t', 'opaque' ] => 'opaque' => \&_create_dt_payload);


  $ffi->attach( accept_distributed_trace_payload          => [ 'newrelic_txn_t', 'string', 'string' ] => 'bool' );
  $ffi->attach( accept_distributed_trace_payload_httpsafe => [ 'newrelic_txn_t', 'string', 'string' ] => 'bool' );

  sub DESTROY
  {
    my($self) = @_;
    $self->end if defined $$self;
  }

};

1;

__END__