File Coverage

blib/lib/Net/WhitePages.pm

Criterion	Covered	Total	%
statement	22	45	48.8
branch	1	4	25.0
condition	1	5	20.0
subroutine	7	12	58.3
pod	3	4	75.0
total	34	70	48.5

package Net::WhitePages;

use strict;
use vars qw($VERSION);

$VERSION = '1.05';

use LWP::Simple qw($ua get);
use Params::Validate qw(validate);
use URI;

use constant API_BASE => 'http://api.whitepages.com';

# Constructor -- simply stores everything given to it
sub new {
    my $class = shift;
    my $args = @_ && ref($_[0]) eq 'HASH' ? shift : { @_ };

    $ua->agent("$class/$VERSION (" . $ua->agent . ")");

    bless {
        DEBUG       => 0,
        TOKEN       => $ENV{'WHITEPAGES_TOKEN'},
        API_VERSION => '1.0',
        %$args,
    } => $class;
}

# ----------------------------------------------------------------------
# find_person()
#
# http://developer.whitepages.com/docs/Methods/find_person
# ----------------------------------------------------------------------
sub find_person {
    my $self = shift;
    return $self->_request(
        validate(@_, {
            'firstname' => 0,
            'lastname'  => 1,
            'house'     => 0,
            'street'    => 0,
            'city'      => 0,
            'state'     => 0,
            'zip'       => 0,
            'areacode'  => 0,
            'metro'     => 0,
        })
    );
}

# ----------------------------------------------------------------------
# reverse_phone
#
# http://developer.whitepages.com/docs/Methods/reverse_phone
# ----------------------------------------------------------------------
sub reverse_phone {
    my $self = shift;
    return $self->_request(
        validate(@_, {
            'phone' => 1,
            'state' => 0,
        }),
    );
}

# ----------------------------------------------------------------------
# reverse_address
#
# http://developer.whitepages.com/docs/Methods/reverse_address
# ----------------------------------------------------------------------
sub reverse_address {
    my $self = shift;
    return $self->_request(
        validate(@_, {
            'house'     => 0,
            'apt'       => 0,
            'street'    => 1,
            'city'      => 0,
            'state'     => 0,
            'zip'       => 0,
            'areacode'  => 0,
        }),
    );
}

# Make the URI
# Takes API_BASE, $self->{ API_VERSION }, and caller
sub _uri {
    my $self = shift;
    my $meth = shift;
    my %p = @_;
    my $uri = URI->new(API_BASE . '/' . $meth . '/' . $self->{ API_VERSION });

    my $t = $self->{ TOKEN } ||
        die "No token defined; can't make a request without a token!\n";

    $p{'api_key'} = $t;
    $p{'outputtype'} = 'Perl';
    $uri->query_form(%p);

    return $uri;
}

# Do the actual request against the whitepages.com server
sub _request {
    my $self = shift;
    my @meth = caller(1);
   (my $meth = $meth[3]) =~ s/.*:://;
    my $uri = $self->_uri($meth, @_);

    if ($self->{ DEBUG }) {
        warn "[DEBUG] Calling `", $uri->canonical, "'\n";
    }

    my $data = get($uri->canonical);

    return eval($data);
}

1;

__END__