File Coverage

blib/lib/Net/Wait.pm

Criterion	Covered	Total	%
statement	30	30	100.0
branch	21	22	95.4
condition	2	3	66.6
subroutine	3	3	100.0
pod			n/a
total	56	58	96.5

package Net::Wait;

use Carp qw( croak );
use Net::EmptyPort qw( wait_port );

our $VERSION = '0.001';

sub import {
    my $package = shift;

    my @tests;
    my %opts = ( timeout => 10 );

    while ( local $_ = shift ) {
        if (/^-verbose$/) {
            $opts{verbose} = 1 and next;
        }

        if (/^-timeout$/) {
            my $timeout = shift;
            croak "Missing value for -timeout when loading $package"
                unless defined $timeout;

            $opts{timeout} = $timeout;
            next;
        }

        if (/^-/) {
            croak "Found unknown option when loading $package: $_";
        }

        push @tests, $_;
    }

    croak "Missing list of host/port pairs when loading $package"
        unless @tests;

    my $limit = '';
    if ( $opts{timeout} > 0 ) {
        $limit = " up to $opts{timeout} second";
        $limit .= 's' if $opts{timeout} != 1;
    }

    for (@tests) {
        my ( $host, $port ) = split /:/, $_, 2;

        croak "Cannot parse host and port from argument to $package: '$_'"
            unless $host && $port;

        warn "Waiting$limit for $_\n" if $opts{verbose};

        wait_port {
            host     => $host,
            port     => $port,
            max_wait => $opts{timeout},
            proto    => 'tcp',
        } or croak "$package timed out while waiting for $_";
    }
}

delete @Net::Wait::{qw( wait_port croak )};

1;

__END__